1 files changed, 52 insertions, 0 deletions
diff --git a/community-testing/mongodb/PKGBUILD b/community-testing/mongodb/PKGBUILD
new file mode 100644
index 000000000..22c2e27d1
--- /dev/null
+++ b/community-testing/mongodb/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Mathias Stearn <mathias@10gen.com>
+# Contributor: Alec Thomas
+
+pkgname=mongodb
+pkgver=2.0.0
+pkgrel=1
+pkgdesc='A high-performance, open source, schema-free document-oriented database.'
+arch=('i686' 'x86_64')
+url='http://www.mongodb.org'
+license=('AGPL3')
+depends=('boost-libs')
+makedepends=('scons' 'boost')
+optdepends=('libpcap: needed for mongosniff')
+backup=('etc/mongodb.conf')
+install="mongodb.install"
+source=("http://downloads.mongodb.org/src/mongodb-src-r${pkgver}.tar.gz"
+        'mongodb.rc'
+        'mongodb.conf')
+md5sums=('52763985c13e06d85bc125c7d3eb03d9'
+         '9c67e00f4626ad761a8f7d4e037a54d7'
+         '4839fe1d638187ca3226e8267b947318')
+
+build() {
+  export SCONSFLAGS="$MAKEFLAGS"
+
+  cd mongodb-src-r${pkgver}
+
+  scons \
+    all \
+    --full
+}
+
+package() {
+  cd mongodb-src-r${pkgver}
+
+  scons \
+    install \
+    --full \
+    --prefix=${pkgdir}/usr
+
+  install -D -m755 ${srcdir}/mongodb.rc \
+    ${pkgdir}/etc/rc.d/mongodb
+  install -D -m644 ${srcdir}/mongodb.conf \
+    ${pkgdir}/etc/mongodb.conf
+  install -d -m700 ${pkgdir}/var/lib/mongodb
+  install -d -m755 ${pkgdir}/var/log/mongodb
+
+  if [ -d ${pkgdir}/usr/lib64 ]; then
+    mv ${pkgdir}/usr/lib64 ${pkgdir}/usr/lib
+  fi
+}