1 files changed, 51 insertions, 0 deletions
diff --git a/community-testing/teeworlds/PKGBUILD b/community-testing/teeworlds/PKGBUILD
new file mode 100644
index 000000000..51ee46ff9
--- /dev/null
+++ b/community-testing/teeworlds/PKGBUILD
@@ -0,0 +1,51 @@
+# Contributor: Allan McRae <allan@archlinux.org>
+# Contributor: Armin 'IsSuE' Praher [issue.at.gmx.dot.at]
+# Contributor: [vEX] <niechift.dot.vex.at.gmail.dot.com>
+# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
+# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
+
+pkgname=teeworlds
+pkgver=0.6.1
+pkgrel=3
+pkgdesc="A multiplayer 2D shooter"
+arch=('i686' 'x86_64')
+url="http://teeworlds.com"
+license=('custom')
+depends=('alsa-lib' 'glu' 'sdl' 'freetype2')
+makedepends=('python2' 'bam' 'mesa')
+replaces=('teewars')
+source=(http://www.teeworlds.com/files/${pkgname}-${pkgver}-source.tar.gz
+        teeworlds.desktop
+		teeworlds.png)
+md5sums=('00de7195ecd1f23596dc3237341af512'
+         '3944aaf7a8c19a83510b2b39c4cddf5f'
+         '44f39e398409232a0e0a431ed46d8cc8')
+
+build() {
+	# Build teeworlds
+	cd ${srcdir}/${pkgname}-*-source
+
+	# Use Python 2
+	sed -i 's/python /python2 /' bam.lua
+
+	bam server_release client_release
+}
+
+package() {
+	cd ${srcdir}/${pkgname}-*-source
+
+	# Install data files
+	mkdir -p ${pkgdir}/usr/share/${pkgname}/data
+	cp -r data/* ${pkgdir}/usr/share/${pkgname}/data
+
+	install -Dm755 ${pkgname} ${pkgdir}/usr/bin/${pkgname}
+	install -Dm755 ${pkgname}_srv ${pkgdir}/usr/bin/${pkgname}_srv
+
+	install -Dm644 ${srcdir}/${pkgname}.desktop \
+		${pkgdir}/usr/share/applications/${pkgname}.desktop
+	install -Dm644 ${srcdir}/${pkgname}.png \
+		${pkgdir}/usr/share/pixmaps/${pkgname}.png
+
+	install -Dm644 license.txt \
+		${pkgdir}/usr/share/licenses/${pkgname}/license.txt
+}