1 files changed, 40 insertions, 0 deletions
diff --git a/community/elinks/PKGBUILD b/community/elinks/PKGBUILD
new file mode 100644
index 000000000..2b9d1139c
--- /dev/null
+++ b/community/elinks/PKGBUILD
@@ -0,0 +1,40 @@
+# $Id: PKGBUILD 88677 2013-04-21 22:16:44Z heftig $
+# Maintainer: Kyle Keen <keenerd@gmail.com>
+# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: damir <damir@archlinux.org>
+# Contributor: Ben <contrasutra@myrealbox.com>
+
+pkgname=elinks
+pkgver=0.13
+_commit="9313aae9062e1d9ff084858fa6844259cd8237d6"
+pkgrel=12
+pkgdesc="An advanced and well-established feature-rich text mode web browser."
+arch=("i686" "x86_64")
+url="http://elinks.or.cz"
+license=('GPL')
+depends=('bzip2' 'expat>=2.0' 'gpm>=1.20.4' 'openssl' 'lua51' 'libidn' 'js185'
+	 'gc' 'tre')
+makedepends=('git')
+source=("git+http://elinks.cz/elinks.git#commit=$_commit")
+md5sums=('SKIP')
+
+build() {
+  cd elinks
+  [ -x configure ] || sh autogen.sh
+  ./configure --prefix=/usr --mandir=/usr/share/man \
+              --sysconfdir=/etc \
+              --disable-smb --without-x --enable-cgi \
+              --enable-leds --enable-256-colors --enable-html-highlight \
+              --with-zlib
+  make
+}
+
+package() {
+  cd elinks
+  make DESTDIR="$pkgdir" install
+  rm -f "$pkgdir/usr/share/locale/locale.alias"
+
+  install -D -m644 "contrib/debian/$pkgname.desktop" \
+    "$pkgdir/usr/share/applications/$pkgname.desktop"
+}