1 files changed, 35 insertions, 0 deletions
diff --git a/community/gnome-subtitles/PKGBUILD b/community/gnome-subtitles/PKGBUILD
new file mode 100644
index 000000000..3e4363d8e
--- /dev/null
+++ b/community/gnome-subtitles/PKGBUILD
@@ -0,0 +1,35 @@
+# $Id: PKGBUILD 87454 2013-03-31 21:57:58Z bgyorgy $
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=gnome-subtitles
+pkgver=1.3
+pkgrel=1
+pkgdesc="Video subtitle editor for GNOME"
+arch=('i686' 'x86_64')
+url="http://gnomesubtitles.org/"
+license=('GPL')
+depends=('gst-plugins-base' 'gconf-sharp' 'gtkspell' 'desktop-file-utils')
+makedepends=('intltool' 'gnome-doc-utils')
+optdepends=('gst-plugins-good: Extra media codecs'
+            'gst-plugins-bad: Extra media codecs'            
+            'gst-plugins-ugly: Extra media codecs'
+            'gst-libav: Extra media codecs')
+options=('!libtool')
+install=$pkgname.install
+source=(http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz)
+md5sums=('b0570134af6626d4e6c018c5f7774964')
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+              --disable-static --disable-schemas-install \
+              --with-gconf-schema-file-dir=/usr/share/gconf/schemas
+  make -j1
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  make DESTDIR="$pkgdir/" install
+}