1 files changed, 38 insertions, 0 deletions
diff --git a/community/gnunet/PKGBUILD b/community/gnunet/PKGBUILD
new file mode 100644
index 000000000..71bae8d67
--- /dev/null
+++ b/community/gnunet/PKGBUILD
@@ -0,0 +1,38 @@
+# $Id: PKGBUILD 90671 2013-05-13 14:25:31Z spupykin $
+# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: wahnby <wahnby@yahoo.fr>
+
+pkgname=gnunet
+pkgver=0.9.5_a
+pkgrel=2
+pkgdesc="A framework for secure peer-to-peer networking"
+arch=('i686' 'x86_64')
+url="http://gnunet.org"
+license=('GPL')
+depends=('gmp' 'libgcrypt' 'libextractor' 'sqlite' 'curl'
+	 'libmicrohttpd' 'libunistring' 'libidn')
+makedepends=('gettext' 'pkgconfig')
+backup=(etc/gnunetd.conf)
+options=('!libtool' '!makeflags')
+install=gnunet.install
+source=(ftp://ftp.gnu.org/gnu/gnunet/gnunet-${pkgver/_/}.tar.gz
+	gnunet.service
+	defaults.conf)
+md5sums=('b0e204cf9711f9799baaeb477992e66a'
+         '54cce3d2415d95b2e5bd1bd88db3a0ea'
+         '0fe23b2ca5b3fc47a0b5645e04406da0')
+
+build() {
+  cd $srcdir/gnunet-${pkgver/_/}
+  sed -i 's|contrib doc|doc|' Makefile.*
+  [ -f Makefile ] || ./configure --prefix=/usr --without-mysql
+  make
+}
+
+package() {
+  cd $srcdir/gnunet-${pkgver/_/}
+  make DESTDIR=$pkgdir install
+  install -D -m0644 $srcdir/defaults.conf $pkgdir/etc/gnunetd.conf
+  rm -rf $pkgdir/usr/include/libltdl $pkgdir/usr/lib/libltdl.* $pkgdir/usr/include/ltdl.h
+  install -Dm0644 $srcdir/$pkgname.service $pkgdir/usr/lib/systemd/system/$pkgname.service
+}