1 files changed, 41 insertions, 0 deletions
diff --git a/community/haskell-blaze-builder/PKGBUILD b/community/haskell-blaze-builder/PKGBUILD
new file mode 100644
index 000000000..03ca1928d
--- /dev/null
+++ b/community/haskell-blaze-builder/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Daniel Micay <danielmicay@gmail.com>
+# Contributor: Arch Haskell Team <>
+# Contributor: Lex Black <autumn-wind at web dot de>
+
+pkgname=haskell-blaze-builder
+_hkgname=blaze-builder
+pkgver=0.3.1.1
+pkgrel=2
+pkgdesc="Efficient buffered output."
+url="http://github.com/meiersi/blaze-builder"
+license=(custom:BSD3)
+arch=('i686' 'x86_64')
+makedepends=('ghc')
+depends=('haskell-bytestring' 'haskell-text')
+source=("http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+install="$pkgname.install"
+sha256sums=('a12506f8afd650e4ed90e1e2379750035f8e83032a2d260eacc3757fe52cdcde')
+
+build() {
+  cd "$srcdir/$_hkgname-$pkgver"
+
+  runhaskell Setup configure -O -p --enable-split-objs --enable-shared \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+    --libsubdir=\$compiler/site-local/\$pkgid
+  runhaskell Setup build
+  runhaskell Setup haddock
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+  cd "$srcdir/$_hkgname-$pkgver"
+  install -Dm744 register.sh "$pkgdir/usr/share/haskell/$pkgname/register.sh"
+  install -m744 unregister.sh "$pkgdir/usr/share/haskell/$pkgname/unregister.sh"
+  install -dm755 "$pkgdir/usr/share/doc/ghc/html/libraries"
+  ln -s /usr/share/doc/$pkgname/html "$pkgdir/usr/share/doc/ghc/html/libraries/$_hkgname"
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  rm -f "$pkgdir/usr/share/doc/$pkgname/LICENSE"
+}