1 files changed, 54 insertions, 0 deletions
diff --git a/community/mongodb/PKGBUILD b/community/mongodb/PKGBUILD
new file mode 100644
index 000000000..f295aee1c
--- /dev/null
+++ b/community/mongodb/PKGBUILD
@@ -0,0 +1,54 @@
+# Maintainer: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Mathias Stearn <mathias@10gen.com>
+# Contributor: Alec Thomas
+
+pkgname=mongodb
+pkgver=1.8.0
+pkgrel=2
+pkgdesc='A high-performance, open source, schema-free document-oriented database.'
+arch=('i686' 'x86_64')
+url='http://www.mongodb.org'
+license=('AGPL3')
+depends=('boost-libs' 'spidermonkey' 'pcre')
+makedepends=('scons' 'boost')
+optdepends=('libpcap: needed for mongosniff')
+backup=('etc/mongodb.conf')
+install="mongodb.install"
+source=("http://downloads.mongodb.org/src/mongodb-src-r${pkgver}.tar.gz"
+        'mongodb.rc'
+        'mongodb.conf')
+md5sums=('243b2776cbe8c70b3bbc402c855f4e82'
+         '859f8f9bb32ef2bd21fec55ae9a87d0a'
+         '9e0ea3f96732bb7811f0b64dace56440')
+
+build() {
+  export SCONSFLAGS="$MAKEFLAGS"
+
+  cd ${pkgname}-src-r${pkgver}
+
+  # scons is "special"
+  sed -i 's/-Wall -Wsign-compare/& -DBOOST_FILESYSTEM_VERSION=2/' SConstruct
+
+  scons \
+    all \
+    --full
+}
+
+package() {
+  cd ${pkgname}-src-r${pkgver}
+
+  scons \
+    install \
+    --full \
+    --prefix=${pkgdir}/usr
+
+  install -D -m755 ${srcdir}/mongodb.rc \
+    ${pkgdir}/etc/rc.d/mongodb
+  install -D -m644 ${srcdir}/mongodb.conf \
+    ${pkgdir}/etc/mongodb.conf
+  install -d -m700 ${pkgdir}/var/state/mongodb
+
+  if [ -d ${pkgdir}/usr/lib64 ]; then
+    mv ${pkgdir}/usr/lib64 ${pkgdir}/usr/lib
+  fi
+}