3 files changed, 89 insertions, 0 deletions
diff --git a/community/pinot/PKGBUILD b/community/pinot/PKGBUILD
new file mode 100644
index 000000000..93d5c3a2e
--- /dev/null
+++ b/community/pinot/PKGBUILD
@@ -0,0 +1,60 @@
+# $Id: PKGBUILD 94041 2013-07-13 12:35:45Z svenstaro $
+# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+# Contributor: William Rea <sillywilly@gmail.com>
+# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
+# Contributor: Alexander Rødseth <rodseth@gmail.com>
+
+pkgname=pinot
+pkgver=1.06
+pkgrel=1
+pkgdesc='Personal search and metasearch tool'
+arch=('i686' 'x86_64')
+url='http://code.google.com/p/pinot-search/'
+license=('GPL')
+depends=('gtkmm3' 'xapian-core' 'libtextcat' 'sqlite' 'libxml++' 'curl' 'gmime' 
+         'dbus-glib' 'shared-mime-info' 'libexif' 'taglib' 'hicolor-icon-theme' 
+         'cairo' 'exiv2' 'boost-libs')
+makedepends=('boost' 'desktop-file-utils')
+optdepends=('unzip: ZIP files extraction'
+            'poppler: PDF to text conversion'
+            'catdvi: DVI to text conversion'
+            'djvulibre: DjVu text extraction'
+            'unrtf: RTF to HTML conversion'
+            'antiword: MS Word to text conversion'
+            'catdoc: XLS and PPT to text conversion')
+options=('!emptydirs')
+install=$pkgname.install
+changelog=$pkgname.changelog
+source=(http://pinot-search.googlecode.com/files/$pkgname-$pkgver.tar.gz)
+sha256sums=('bba6f412553890ef7cccd6d7bb28df9a6c4d122ea74a2902e5de33953cd1872d')
+
+build() {
+  cd $srcdir/$pkgname-$pkgver
+  x='/usr/share/libtextcat/'
+  sed -i 's|/LM/russian.lm|/LM/russian-windows1251.lm|' textcat_conf.txt
+  sed -i "s|$x|${x}LM/|" \
+    textcat_conf.txt \
+    textcat3_conf.txt \
+    textcat31_conf.txt \
+    textcat32_conf.txt
+  sed -i -e "s|.*russian$|${x}LM/russian-iso8859_5.lm   russian-iso8859_5\n\
+${x}LM/russian-koi8_r.lm      russian-koi8_r\n\
+${x}LM/russian-windows1251.lm russian-windows1251|" textcat3_conf.txt
+
+  LIBS="-lboost_system" ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --libexecdir=/usr/lib \
+    --enable-gtkmm3=yes \
+    --enable-mempool=no
+  make
+}
+
+package() {
+  cd $srcdir/$pkgname-$pkgver
+
+  make DESTDIR=$pkgdir install
+}
+
+# vim:set ts=2 sw=2 et:
diff --git a/community/pinot/pinot.changelog b/community/pinot/pinot.changelog
new file mode 100644
index 000000000..4cf1a68a2
--- /dev/null
+++ b/community/pinot/pinot.changelog
@@ -0,0 +1,14 @@
+2012-09-29 Alexander Rødseth <rodseth@gmail.com>
+	* fix FS#31510, adding --enable-mempool=no
+
+2012-09-12 Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
+	* pinot 1.01-1
+
+2012-07-31  Eric Belanger  <eric@archlinux.org>
+	* pinot 1.0-2 : Rebuild against exiv2 0.23, Add boost-libs depends
+
+2012-07-14 Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
+	* pinot 1.0-1
+
+2011-12-18 Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
+	* pinot 0.98-1
diff --git a/community/pinot/pinot.install b/community/pinot/pinot.install
new file mode 100644
index 000000000..55ab40426
--- /dev/null
+++ b/community/pinot/pinot.install
@@ -0,0 +1,15 @@
+post_install() {
+  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+  echo "Starting with 0.63, the service is auto-started. "
+  echo "The file that enables this is located at "
+  echo "/etc/xdg/autostart/pinot-dbus-daemon.desktop"
+  echo "Delete this file if you don't want the auto-start."
+}
+
+post_upgrade() {
+  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}
+
+post_remove() {
+  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}