1 files changed, 43 insertions, 0 deletions
diff --git a/extra/kdesdk-lokalize/PKGBUILD b/extra/kdesdk-lokalize/PKGBUILD
new file mode 100644
index 000000000..2ec1b912d
--- /dev/null
+++ b/extra/kdesdk-lokalize/PKGBUILD
@@ -0,0 +1,43 @@
+# $Id$
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+
+pkgname=kdesdk-lokalize
+pkgver=4.11.0
+pkgrel=1
+pkgdesc='Computer-Aided Translation System'
+url='http://kde.org/applications/development/lokalize/'
+arch=('i686' 'x86_64')
+license=('GPL' 'LGPL' 'FDL')
+groups=('kde' 'kdesdk')
+depends=('kdebase-runtime' 'kdebindings-python2' 'kdesdk-strigi-analyzers')
+makedepends=('cmake' 'automoc4')
+optdepends=('translate-toolkit: enable extra python script')
+install=${pkgname}.install
+source=("http://download.kde.org/stable/${pkgver}/src/lokalize-${pkgver}.tar.xz"
+        'fix-python2-path.patch')
+sha1sums=('b0e606806db9188c95e49d139ba58d417232d3a3'
+          '07db42bbcae402c292eebf002e549b04162621c5')
+
+prepare() {
+  cd lokalize-${pkgver}
+  patch -p2 -i "${srcdir}"/fix-python2-path.patch
+}
+
+build() {
+  mkdir build
+  cd build
+  cmake ../lokalize-${pkgver} \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DKDE4_BUILD_TESTS=OFF \
+    -DCMAKE_INSTALL_PREFIX=/usr
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR=$pkgdir install
+
+  # Fix python 2 path
+  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
+    "${pkgdir}"/usr/share/apps/lokalize/scripts/odf/xliffmerge.py
+}