1 files changed, 43 insertions, 0 deletions
diff --git a/gnome-unstable/gthumb/PKGBUILD b/gnome-unstable/gthumb/PKGBUILD
new file mode 100644
index 000000000..6af778627
--- /dev/null
+++ b/gnome-unstable/gthumb/PKGBUILD
@@ -0,0 +1,43 @@
+# $Id: PKGBUILD 167923 2012-10-03 20:33:57Z heftig $
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor: Jan de Groot <jgc@archlinux.org>
+# Contributor: Tobias Kieslich <tobias@justdreams.de>
+
+pkgname=gthumb
+pkgver=3.1.1
+pkgrel=1
+pkgdesc="Image browser and viewer for the GNOME Desktop"
+arch=(i686 x86_64)
+license=('GPL')
+url="http://live.gnome.org/gthumb"
+depends=('desktop-file-utils' 'hicolor-icon-theme' 'dconf' 'librsvg' 'clutter-gtk'
+         'gstreamer0.10-base' 'gsettings-desktop-schemas' 'libwebp')
+makedepends=('intltool' 'gnome-doc-utils' 'libchamplain' 'libopenraw' 'exiv2' 'libsoup-gnome'
+             'brasero' 'librsvg' 'libopenraw' 'liboauth')
+optdepends=('libopenraw: read RAW files'
+            'exiv2: metadata support'
+            'libchamplain: map viewer'
+            'brasero: burn discs'
+            'libsoup-gnome: web albums'
+            'liboauth: web albums')
+options=('!libtool' '!emptydirs')
+install=gthumb.install
+source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
+sha256sums=('7e725ba38d1220ed09d0657dd365982547856aa0d03c775891de33d04c31e332')
+
+build() {
+  cd $pkgname-$pkgver
+  
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --disable-static \
+      --enable-libchamplain --enable-libopenraw
+  
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/    if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/      func_append compile_command " -Wl,-O1,--as-needed"\n      func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
+
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}