1 files changed, 88 insertions, 0 deletions
diff --git a/libre/qupzilla-libre/PKGBUILD b/libre/qupzilla-libre/PKGBUILD
new file mode 100644
index 000000000..3d23a89f8
--- /dev/null
+++ b/libre/qupzilla-libre/PKGBUILD
@@ -0,0 +1,88 @@
+# $Id: PKGBUILD 104845 2014-01-27 14:16:51Z speps $
+# Maintainer: speps <speps at aur dot archlinux dot org>
+# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
+
+_pkgbase=qupzilla
+pkgbase=qupzilla-libre
+pkgname=(qupzilla-libre qupzilla-libre-qt5)
+pkgver=1.6.1
+pkgrel=1
+arch=(i686 x86_64 mips64el)
+url="http://www.qupzilla.com/"
+license=('GPL3')
+makedepends=('qtwebkit' 'qt5-webkit' 'qt5-script' 'hunspell')
+optdepends=('bash-completion: bash completion support')
+source=("$_pkgbase-$pkgver.tar.gz::https://github.com/QupZilla/qupzilla/archive/v$pkgver.tar.gz"
+         'searchenginesmanager.cpp.sed'
+         'speeddial.cpp.sed'
+         'start.html.sed')
+noextract=("$_pkgbase-$pkgver.tar.gz")
+install="$_pkgbase.install"
+md5sums=('ca6fee487c9871d37d2dd09b3617b88f'
+         '1d926e97a5b287d40fb695f6516f2a06'
+         '0f166fa102af975b3b8ac030d477e9b8'
+         '77120a0c39ba8254e5b2c273910f029a')
+
+prepare() {
+  # extract
+  mkdir -p qt{4,5}
+  bsdtar --strip-components 1 -zxf $_pkgbase-$pkgver.tar.gz -C qt4
+  bsdtar --strip-components 1 -zxf $_pkgbase-$pkgver.tar.gz -C qt5
+
+  # configure
+  export USE_WEBGL=true \
+         QUPZILLA_PREFIX=/usr/
+
+  # remove Google and Youtube support, replaces it to DDG HTML
+  cd qt4
+  sed -i -f $srcdir/searchenginesmanager.cpp.sed src/lib/opensearch/searchenginesmanager.cpp
+  sed -i -f $srcdir/speeddial.cpp.sed src/lib/plugins/speeddial.cpp
+  sed -i -f $srcdir/start.html.sed src/lib/data/html/start.html
+
+  cd ../qt5
+  sed -i -f $srcdir/searchenginesmanager.cpp.sed src/lib/opensearch/searchenginesmanager.cpp
+  sed -i -f $srcdir/speeddial.cpp.sed src/lib/plugins/speeddial.cpp
+  sed -i -f $srcdir/start.html.sed src/lib/data/html/start.html
+}
+
+build() {
+  cd qt4
+  qmake-qt4
+  make
+
+  cd ../qt5
+  qmake
+  make
+}
+
+package_qupzilla-libre() {
+  pkgdesc="Cross-platform QtWebKit browser, without non-privacy search providers"
+  depends=('qtwebkit' 'hunspell')
+  provides=qupzilla=$pkgver
+  conflicts=qupzilla
+  replaces=qupzilla
+
+  cd qt4
+  make INSTALL_ROOT="$pkgdir/" install
+
+  # zsh completion
+  install -Dm644 linux/completion/_$_pkgbase \
+    "$pkgdir/usr/share/zsh/site-functions/_$_pkgbase"
+}
+
+package_qupzilla-libre-qt5() {
+  pkgdesc="Cross-platform QtWebKit browser (Qt5), without non-privacy search providers"
+  depends=('qt5-webkit' 'qt5-script' 'hunspell' 'desktop-file-utils' 'hicolor-icon-theme')
+  provides=('qupzilla-libre' "qupzilla-qt5=$pkgver")
+  conflicts=('qupzilla-libre' 'qupzilla-qt5')
+  replaces=qupzilla-qt5
+
+  cd qt5
+  make INSTALL_ROOT="$pkgdir/" install
+
+  # zsh completion
+  install -Dm644 linux/completion/_$_pkgbase \
+    "$pkgdir/usr/share/zsh/site-functions/_$_pkgbase"
+}
+
+# vim:set ts=2 sw=2 et: