1 files changed, 53 insertions, 0 deletions
diff --git a/pcr/netatalk/PKGBUILD b/pcr/netatalk/PKGBUILD
new file mode 100644
index 000000000..b16132dab
--- /dev/null
+++ b/pcr/netatalk/PKGBUILD
@@ -0,0 +1,53 @@
+# Maintainer: SJ_UnderWater
+# Based on netatalk package :
+# Maintainer: Dominik Dingel <mail at wodar dot de>
+# Contributor: William Udovich <nerdzrule7 at earthlink dot net>
+# Contributor: Farhan Yousaf <farhany at xaviya dot com>
+
+pkgname=netatalk
+pkgver=3.0.4
+pkgrel=2
+pkgdesc='A kernel-level implementation of AFP services'
+arch=('i686' 'x86_64' 'mips64el')
+url='http://netatalk.sourceforge.net'
+license=('GPL')
+depends=('avahi>=0.6' 'libldap' 'libgcrypt>=1.2.3' 'libevent' 'python' 'dbus-glib')
+replaces=('netatalk-git' 'netatalk2')
+backup=('etc/afp.conf'
+	'etc/extmap.conf')
+options=('!libtool')
+install=$pkgname.install
+changelog=$pkgname.changelog
+source=(http://iweb.dl.sourceforge.net/project/$pkgname/$pkgname/$pkgver/$pkgname-$pkgver.tar.bz2)
+md5sums=('f455505884a6aea307640d46a6577fd1')
+
+prepare() {
+	cd $pkgname-$pkgver
+
+	sed -i -e 's:AX_CHECK_DOCBOOK:[AX_CHECK_DOCBOOK]:' -e 's:"/lib/systemd:"/usr/lib/systemd:' -e 's/x"linux/x"generic/' macros/netatalk.m4
+	sed -i 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' {configure.ac,libevent/configure.in}
+	cp /usr/share/automake*/missing .
+
+	autoreconf -i
+}
+
+build() {
+	cd $pkgname-$pkgver
+
+
+  ./configure --prefix=/usr \
+              --sbindir=/usr/bin \
+              --localstatedir=/var/state \
+              --sysconfdir=/etc \
+              --with-init-style=systemd \
+              --with-cracklib \
+              --with-cnid-cdb-backend \
+              --enable-pgp-uam \
+              --with-libevent=no
+
+	make
+}
+package() {
+	cd $pkgname-$pkgver
+	make DESTDIR="$pkgdir" install
+}