1 files changed, 42 insertions, 0 deletions
diff --git a/pcr/tinc-pre/PKGBUILD b/pcr/tinc-pre/PKGBUILD
new file mode 100644
index 000000000..ebbd4cc3f
--- /dev/null
+++ b/pcr/tinc-pre/PKGBUILD
@@ -0,0 +1,42 @@
+pkgname=tinc-pre
+pkgver=1.1pre7
+pkgrel=2
+pkgdesc="VPN (Virtual Private Network) daemon (Pre-release)"
+arch=(i686 x86_64)
+url="http://www.tinc-vpn.org/"
+license=('GPL')
+depends=('lzo2' 'zlib' 'openssl')
+optdepends=('wxpython: gui support')
+provides=('tinc-pre')
+conflicts=('tinc')
+source=(http://www.tinc-vpn.org/packages/tinc-$pkgver.tar.gz{,.sig}
+        tincd@.service)
+
+build() {
+  cd "$srcdir/tinc-$pkgver"
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --sbindir=/usr/bin
+  make
+}
+
+package() {
+  cd "$srcdir/tinc-$pkgver"
+
+  make DESTDIR="$pkgdir" install
+
+  install -dm755 "$pkgdir"/usr/share/tinc/examples
+  tar xozvf doc/sample-config.tar.gz -C $pkgdir/usr/share/tinc/examples
+  find "$pkgdir"/usr/share/tinc/examples -type f -exec chmod 644 {} +
+  find "$pkgdir"/usr/share/tinc/examples -type d -exec chmod 755 {} +
+
+  install -Dm644 "$srcdir/tincd@.service" \
+                 "$pkgdir/usr/lib/systemd/system/tincd@.service"
+
+  sed -e 's,#!/usr/bin/python,#!/usr/bin/python2,' \
+      -i $pkgdir/usr/bin/tinc-gui
+}
+sha1sums=('62a014356864c3a5204edd6e934f3ee575760cfc'
+          'SKIP'
+          '6ab485732bb6c59e7e0e162f22251a0f554ec69c')
+sha256sums=('ff330627ad0d6ce1233408bb75b11d7506be13eb0c802ff1657866d97545074b'
+            'SKIP'
+            '43d086b76e2a6ff6d91a2ace2d6d048fc7109fefecd5047ab6c437ba0e9252ed')