1 files changed, 45 insertions, 0 deletions
diff --git a/social/gnuhealth/PKGBUILD b/social/gnuhealth/PKGBUILD
new file mode 100644
index 000000000..f1da528ff
--- /dev/null
+++ b/social/gnuhealth/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: SpepS <dreamspepser at yahoo dot it>
+
+pkgname=gnuhealth
+pkgver=1.6.1
+pkgrel=1
+pkgdesc="A free Health and Hospital Information System"
+arch=(any)
+url="http://health.gnu.org/"
+license=('GPL3')
+depends=('trytond')
+source=("http://ftp.gnu.org/gnu/health/$pkgname-$pkgver.tar.gz")
+md5sums=('fef8c811ca6de3fdd6e2430d644e13c9')
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  # python2 fixes
+  export PYTHON=python2
+  sed -i '/TRYTON_PATH/s/python/&2/' configure
+
+  # makefile fixes
+  sed -e '/install:/a\\tinstall -d $(DESTDIR)$(tryton_modules)/' \
+      -e 's/$(tryton/$(DESTDIR)&/' -i Makefile.in
+
+  # mv man file
+  mv health/man .
+
+  ./configure --prefix=/usr
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+  make MANTARGET="$pkgdir/usr/share/man/man1" \
+       DESTDIR="$pkgdir/" install
+
+  # man
+  install -Dm644 man/$pkgname.1 \
+    "$pkgdir/usr/share/man/man1/$pkgname.1"
+
+  # python2 fix
+  sed -i 's/env python/&2/' \
+    `grep -rl 'env python' "$pkgdir"`
+}
+
+# vim:set ts=2 sw=2 et: