blob: cca3dbd9778db3e64e872834b308aee948b82139 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 86453 2013-03-17 13:59:10Z bpiotrowski $
# Maintainer: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Alexander Fehr <pizzapunk gmail com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=aria2
pkgver=1.16.4
pkgrel=1
pkgdesc='Download utility that supports HTTP(S), FTP, BitTorrent, and Metalink'
arch=('i686' 'x86_64')
url='http://aria2.sourceforge.net/'
license=('GPL')
depends=('gnutls' 'libxml2' 'sqlite' 'c-ares' 'ca-certificates')
checkdepends=('cppunit')
source=(http://downloads.sourceforge.net/aria2/aria2-${pkgver}.tar.bz2)
sha256sums=('7fb5360570ee626b428f9450244435734fbc9e979994e3e61eb672e8ed970319')
build() {
cd $pkgname-$pkgver
./configure \
--prefix=/usr \
--with-ca-bundle=/etc/ssl/certs/ca-certificates.crt
make
}
check() {
cd $pkgname-$pkgver
make check
}
package() {
cd $pkgname-$pkgver
make DESTDIR=${pkgdir} install
# add bash completion (aria2 automatically installs to a temporary target directory)
install -d ${pkgdir}/usr/share/bash-completion/completions
install -m644 ${pkgdir}/usr/share/doc/aria2/bash_completion/aria2c \
${pkgdir}/usr/share/bash-completion/completions
rm -rf ${pkgdir}/usr/share/doc/aria2/bash_completion
}
|
