blob: 0cb7c6debfbb173e8a44f10b1c29aa8a11f201d9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id: PKGBUILD 110923 2014-05-09 16:39:02Z anatolik $
# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor: Martin Schmölzer <mschmoelzer@gmail.com>
_target=arm-none-eabi
pkgname=$_target-gdb
pkgver=7.7.1
pkgrel=1
pkgdesc='The GNU Debugger for the ARM EABI (bare-metal) target'
arch=(i686 x86_64)
url='http://www.gnu.org/software/gdb/'
license=(GPL3)
depends=(xz ncurses expat python2)
makedepends=(texinfo)
optdepends=('openocd: for debugging JTAG targets'
'stlink: for debugging over STLINK')
options=(!emptydirs)
source=(ftp://ftp.gnu.org/gnu/gdb/gdb-$pkgver.tar.bz2)
sha256sums=('0dbd5260406f1b0c70fcf027c6488527fadde0cd9bb574593491fe076eb03aa5')
build() {
cd gdb-$pkgver
sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" libiberty/configure
./configure --target=$_target \
--prefix=/usr \
--enable-multilib \
--enable-interwork \
--with-system-readline \
--disable-nls \
--with-python=/usr/bin/python2 \
--with-system-gdbinit=/etc/gdb/gdbinit
make
}
package() {
cd gdb-$pkgver
make DESTDIR="$pkgdir" install
# Following files conflict with 'gdb' package
rm -r "$pkgdir"/usr/share/info
# TOTHINK: we remove python module used for debugging. It means arm-*-gdb alone will not be able to debug and 'gdb' package
# should be installed. File a bug upstream - ask a separate python module folder for cross tools.
rm -r "$pkgdir"/usr/share/gdb
rm -r "$pkgdir"/usr/include/gdb
rm "$pkgdir"/usr/share/man/man1/gdb*
rm -r "$pkgdir"/usr/share/man/man5
}
|
