blob: dc36a979ba32ca0b76181f5bbd285290908ae166 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 90005 2013-05-06 19:36:16Z foutrelis $
# Maintainer: Kyle Keen <keenerd@gmail.com>
# Contributor: Mateusz Herych <heniekk@gmail.com>
# Contributor: Filippo 'JoeyrS' Civiletti <joeyrs@gmail.com>
pkgname=armagetronad
pkgver=0.2.8.3.2
pkgrel=4
pkgdesc='A Tron Clone in 3D.'
arch=('i686' 'x86_64')
url='http://armagetronad.net/'
license=('GPL')
depends=('sdl_image' 'libxml2' 'sdl_mixer' 'ftgl')
optdepends=('python2: language updater')
source=(http://downloads.sourceforge.net/sourceforge/armagetronad/armagetronad-$pkgver.src.tar.gz)
md5sums=('f7796de4ef50bd33553e0a3f93fd67e6')
build() {
cd "$srcdir/armagetronad-$pkgver"
# python2 fix
sed -i 's_#!/usr/bin/python_#!/usr/bin/python2_' language/update.py
sed -i 's|FTGL.h|ftgl.h|g' configure
sed -i 's|png_check_sig|png_sig_cmp|g' configure
./configure --prefix=/usr \
--sysconfdir=/etc \
--mandir=/usr/share/man \
--disable-games \
--enable-automakedefaults \
--disable-uninstall
make
}
package() {
cd "$srcdir/armagetronad-$pkgver"
make DESTDIR="$pkgdir" install
install -D -m 644 "desktop/armagetronad.desktop" "$pkgdir/usr/share/applications/armagetronad.desktop"
install -d "$pkgdir/usr/share/pixmaps/"
ln -s /usr/share/armagetronad/desktop/icons/large/armagetronad.png \
"$pkgdir/usr/share/pixmaps/armagetronad.png"
mv "$pkgdir/usr/bin/armagetronad" "$pkgdir/usr/bin/armagetronad_bin"
printf "#!/bin/bash\n/usr/bin/armagetronad_bin --configdir /etc/armagetronad --datadir /usr/share/armagetronad" > "$pkgdir/usr/bin/armagetronad"
chmod +x "$pkgdir/usr/bin/armagetronad"
}
|
