blob: 0a6019562bb4bfb1b313c27df6f87b552216e39b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id: PKGBUILD 106659 2014-03-06 11:40:25Z flexiondotorg $
# Maintainer : Martin Wimpress <code@flexion.org>
pkgname=atril
pkgver=1.8.0
pkgrel=1
pkgdesc="Simply a document viewer"
url="http://mate-desktop.org"
arch=('i686' 'x86_64')
license=('GPL')
depends=('dconf' 'dbus' 'desktop-file-utils' 'gtk2' 'libsm' 'libspectre'
'mate-desktop' 'mate-icon-theme' 'poppler-glib' 'zlib')
makedepends=('caja' 'djvulibre' 'gobject-introspection' 'libgxps' 'mate-common'
'perl-xml-parser' 'texlive-bin' 'yelp-tools')
optdepends=('caja: Document Properties extension'
'djvulibre: DjVu support'
'libgxps: XPS support'
'p7zip: cbz and cb7 compressed comic books'
'texlive-bin: DVI support'
'unrar: cbr compressed comic books'
'yelp: for reading MATE help documents')
replaces=('mate-document-viewer')
provides=('mate-document-viewer')
conflicts=('mate-document-viewer')
options=('!emptydirs')
groups=('mate-extra')
source=("http://pub.mate-desktop.org/releases/1.8/${pkgname}-${pkgver}.tar.xz")
sha1sums=('8327437ba12df61326b83342cea746d1764727d0')
install=${pkgname}.install
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure \
--prefix=/usr \
--libexecdir=/usr/lib/${pkgname} \
--with-gtk=2.0 \
--enable-gtk-doc \
--enable-djvu \
--enable-dvi \
--enable-t1lib \
--enable-pixbuf \
--enable-comics \
--enable-xps \
--enable-introspection \
--disable-static
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
