blob: 83adc360aa4b043eb1980ec5c1df1fd1234b2305 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# $Id: PKGBUILD 108593 2014-03-29 12:43:06Z lfleischer $
# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Dale Blount <dale@archlinux.org>
# Contributor: Manolis Tzanidakis
pkgname=autofs
pkgver=5.0.9
pkgrel=1
pkgdesc='A kernel-based automounter for Linux.'
arch=('i686' 'x86_64')
url='http://freshmeat.net/projects/autofs'
license=('GPL2')
depends=('libxml2')
makedepends=('libldap' 'krb5' 'kmod')
optdepends=('krb5: for LDAP support')
backup=('etc/autofs/auto.master'
'etc/autofs/auto.misc'
'etc/autofs/auto.net'
'etc/autofs/auto.smb'
'etc/autofs/autofs_ldap_auth.conf'
'etc/default/autofs')
options=(!makeflags)
source=("http://www.kernel.org/pub/linux/daemons/${pkgname}/v5/${pkgname}-${pkgver}.tar.xz")
sha256sums=('81ab99ee1656a10ecaffe7933c26e8fc720f0b639ed47ab52adc66cdd868fd5c')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i -e 's|/etc/auto.misc|/etc/autofs/auto.misc|' \
-e 's|/etc/auto.master.d|/etc/autofs/auto.master.d|' samples/auto.master
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc/autofs --sbindir=/usr/bin \
--with-mapdir=/etc/autofs --without-hesiod \
--enable-ignore-busy --with-systemd
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make INSTALLROOT="${pkgdir}" install
rm -r "$pkgdir/run"
install -dm755 "$pkgdir/etc/autofs/auto.master.d"
}
# vim:set ts=2 sw=2 et:
|
