blob: 71e7e026a388821e26abde81d7eb55eb8d825d8e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Alexandre Filgueira <alexfilgueira@cinnarch.com>
# Based on gnome-screensaver package:
# Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Jan de Groot <jgc@archlinux.org>
pkgname=cinnamon-screensaver
pkgver=2.2.2
pkgrel=1
pkgdesc="Screensaver designed to integrate well with the Cinnamon desktop."
arch=('i686' 'x86_64')
license=('GPL')
url="https://github.com/linuxmint/cinnamon-screensaver"
backup=(etc/pam.d/cinnamon-screensaver)
depends=('cinnamon-desktop' 'cinnamon-translations' 'dbus-glib' 'libgnomekbd')
makedepends=('intltool' 'gnome-common')
source=($pkgname-$pkgver.tar.gz::https://github.com/linuxmint/cinnamon-screensaver/archive/$pkgver.tar.gz
fix-high-cpu.patch
cinnamon-screensaver.pam)
sha256sums=('6c95f6a1ec8437b63c6b04422527301f4aceeffd3ceb2c034d19bef8deb77333'
'6cb02c9a9df6d4366538b8faffe9d53cf9165871352fe01befb77e8ea92ea736'
'b6ea9e2eb586d94bcabb617a8f1c2958111df87afdbb51f645882bccdc15cbda')
prepare() {
cd $pkgname-$pkgver
# Fix high CPU usage (FS#39951)
patch -Np1 -i ../fix-high-cpu.patch
}
build() {
cd $pkgname-$pkgver
./autogen.sh --prefix=/usr --sysconfdir=/etc \
--libexecdir=/usr/lib/cinnamon-screensaver \
--localstatedir=/var \
--with-mit-ext --with-systemd
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
install -Dm644 ../cinnamon-screensaver.pam "$pkgdir/etc/pam.d/cinnamon-screensaver"
}
|
