blob: bf777ffd02dead3e3fbbf3813c50487dd5a271cf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# $Id: PKGBUILD 111753 2014-05-23 11:17:45Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: T. Jameson Little <t.jameson.little at gmail dot com>
# Contributor: Usagi Ito <usagi@WonderRabbitProject.net>
# Contributor: siasia <http://pastebin.com/qsBEmNCw>
# Contributor: Julien Nicoulaud <julien.nicoulaud@gmail.com>
pkgname=dart
pkgver=1.4.0
pkgrel=1
pkgdesc='The dart programming language SDK'
arch=('x86_64' 'i686')
url='http://www.dartlang.org/'
license=('BSD')
optdepends=('java-runtime: for dartanalyzer')
makedepends=('setconf')
options=('!strip')
if [[ $CARCH == x86_64 ]]; then
source=("$pkgname-$pkgver-64.zip::http://storage.googleapis.com/dart-archive/channels/stable/release/latest/sdk/dartsdk-linux-x64-release.zip")
sha256sums=('3c9c8afef58b49e0d03add60ee54e5c4d77c95990fadb16bc0c9045cc3ed34de')
else
source=("$pkgname-$pkgver-32.zip::http://storage.googleapis.com/dart-archive/channels/stable/release/latest/sdk/dartsdk-linux-ia32-release.zip")
sha256sums=('107a67bc5a133551ba7c4ebc266fd521bae8133f79509c57bbe4d07b607926f9')
fi
prepare() {
# Fix permissions
find "$pkgname-sdk" -type d -exec chmod 0755 '{}' + \
-or -type f -exec chmod 0644 '{}' +
chmod +x "$pkgname-sdk/bin/"*
# Fix paths
cd "$pkgname-sdk/bin"
setconf dart2js BIN_DIR "/opt/$pkgname-sdk/bin"
setconf dart2js PROG_NAME "/opt/$pkgname-sdk/bin/dart2js"
setconf dartanalyzer SCRIPT_DIR "/opt/$pkgname-sdk/bin"
setconf docgen BIN_DIR "/opt/$pkgname-sdk/bin"
setconf pub BIN_DIR "/opt/$pkgname-sdk/bin"
setconf pub SDK_DIR "/opt/$pkgname-sdk/"
setconf dartfmt BIN_DIR "/opt/$pkgname-sdk/bin"
setconf dartfmt SDK_DIR "/opt/$pkgname-sdk/"
# Fix missing "fi" and missing newline
echo -e "fi\n" >> pub
# Extract license (AUTHORS and LICENSE files are missing)
head -n5 "../include/dart_api.h" > ../../LICENSE
}
package() {
# Create directories
install -d "$pkgdir"{"/opt/$pkgname-sdk",/usr/{bin,"share/doc/$pkgname-sdk"}}
# Package the files
cp -a "$pkgname-sdk/"* "$pkgdir/opt/$pkgname-sdk/"
# Set up symbolic links for the executables
for f in dart dart2js dartanalyzer docgen pub dartfmt; do
ln -s "/opt/$pkgname-sdk/bin/$f" "$pkgdir/usr/bin/$f"
done
# Package samples and documentation
for f in samples about.html about_files; do
echo mv "$pkgdir/opt/$pkgname-sdk/$f" "$pkgdir/usr/share/doc/$pkgname/"
done
# BSD License
install -Dm644 LICENSE \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=2 sw=2 et:
|
