blob: 636d2e762f05c19ee9af91ddea6f2fb801358aba (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 49764 2011-06-21 00:08:54Z heftig $
# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
# Contributor: dieghen89 <dieghen89@gmail.com>
# Contributor: Alessio 'Bl@ster' Biancalana <dottorblaster@gmail.com>
pkgname=docky
pkgver=2.1.3
pkgrel=1
pkgdesc="The finest dock no money can buy!"
url="https://launchpad.net/docky"
arch=(i686 x86_64)
license=(GPL)
depends=(gnome-desktop-sharp gnome-keyring-sharp gtk2 mono-addins
hicolor-icon-theme ndesk-dbus-glib notify-sharp-svn xdg-utils
desktop-file-utils dockmanager gio-sharp dbus-sharp-glib gconf-sharp)
makedepends=(intltool libgnome-sharp)
options=('!libtool' '!emptydirs')
install=docky.install
source=("http://launchpad.net/$pkgname/${pkgver%.*}/$pkgver/+download/$pkgname-$pkgver.tar.gz")
md5sums=('7a40c25dff6b71c346e7791533f05b5f')
build() {
cd "$srcdir/$pkgname-$pkgver"
export MONO_SHARED_DIR="$srcdir/.wabi"
mkdir -p "$MONO_SHARED_DIR"
./configure \
--prefix=/usr \
--sysconfdir=/etc
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 install
mkdir -p "$pkgdir/usr/share/gconf/schemas"
gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/docky.schemas" "$pkgdir"/etc/gconf/schemas/*.schemas
rm -rf "$pkgdir/etc/gconf"
}
|
