blob: d820a84797935e4d1afba73d8987129b7345cfa7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
# $Id: PKGBUILD 109642 2014-04-17 10:33:05Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Jeff 'codemac' Mickey <jeff@archlinux.org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
pkgname=ejabberd
pkgver=13.12
pkgrel=2
pkgdesc="Jabber server written in Erlang"
arch=('x86_64' 'i686')
url="http://www.ejabberd.im/"
license=("GPL")
depends=('expat' 'openssl' 'zlib' 'erlang-nox' 'pam' 'iproute2' 'erlang-unixodbc' 'libyaml')
makedepends=('git' 'rebar')
backup=('etc/ejabberd/ejabberd.yml'
'etc/ejabberd/ejabberdctl.cfg'
'etc/logrotate.d/ejabberd')
install=$pkgname.install
replaces=('ejabberd-mod_mysql' 'ejabberd-mod_mysql-svn'
'ejabberd-mod_pgsql' 'ejabberd-mod_pgsql-svn')
source=("$pkgname-$pkgver.tar.gz::https://github.com/processone/ejabberd/archive/$pkgver.tar.gz"
"p1_cache_tab::git://github.com/processone/cache_tab"
"p1_tls::git://github.com/processone/tls"
"p1_stringprep::git://github.com/processone/stringprep"
"p1_xml::git://github.com/processone/xml"
"p1_yaml::git://github.com/processone/p1_yaml"
"git://github.com/rds13/xmlrpc"
"p1_pam::git://github.com/processone/epam"
"p1_zlib::git://github.com/processone/zlib"
"git://github.com/basho/lager"
"p1_iconv::git://github.com/processone/eiconv"
"git://github.com/DeadZen/goldrush.git"
"p1_mysql::git://github.com/processone/mysql.git"
"p1_pgsql::git://github.com/processone/pgsql.git"
"p1_stun::git://github.com/processone/stun"
"git://github.com/davisp/jiffy"
"git://github.com/cmullaparthi/ibrowse"
"git://github.com/esl/lhttpc"
"$pkgname.logrotate"
"ejabberd.service"
"crash-fix.patch"
"https://github.com/processone/ejabberd/commit/7af7b7d3f0c4bf399fb7db54c38090c8d1a25873.patch"
"https://github.com/processone/ejabberd/commit/d97b4fd9ca36858a12bc5e6841334cde4c8f0431.patch")
md5sums=('6eadb6f190d55c8a679de5496ca0c4a9'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'f97c8a96160f30e0aecc9526c12e6606'
'a437aff9d7d477fb036d527205617e18'
'ef3dd667dec1627c1597c7f6f3cfcd4a'
'aa8cf60e39b0deee112e20f305022ade'
'5f2cada6c6504f1e3874ef33606751c8')
prepare() {
cd "$srcdir/$pkgname-$pkgver"
patch -p1 <$srcdir/crash-fix.patch
# erlang 17 fix
patch -p1 <$srcdir/d97b4fd9ca36858a12bc5e6841334cde4c8f0431.patch
patch -p1 <$srcdir/7af7b7d3f0c4bf399fb7db54c38090c8d1a25873.patch
mkdir -p "$srcdir/$pkgname-$pkgver/deps"
for i in goldrush lager p1_cache_tab p1_iconv p1_pam \
p1_stringprep p1_tls p1_xml p1_yaml p1_zlib xmlrpc \
p1_mysql p1_pgsql p1_stun jiffy ibrowse lhttpc; do
rm -rf "$srcdir/$pkgname-$pkgver/deps/$i"
mv $srcdir/$i "$srcdir/$pkgname-$pkgver/deps"
done
sed -i 's|%%% @author.*|%%% @author Oscar Hellstrom <oscar@hellstrom.st>|g' deps/lhttpc/src/lhttpc.app.src
}
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--enable-all
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -d "$pkgdir/var/lib/$pkgname"
install -D -m0644 "$srcdir/$pkgname.logrotate" "$pkgdir/etc/logrotate.d/$pkgname"
chmod ug+r "$pkgdir/etc/$pkgname/"*
mkdir -p $pkgdir/usr/bin
mv $pkgdir/usr/sbin/ejabberdctl $pkgdir/usr/bin/ejabberdctl
chmod a+rx "$pkgdir/usr/bin/ejabberdctl" "$pkgdir/usr/lib/ejabberd/priv/bin/captcha.sh"
rm -rf "$pkgdir/var/lock" "$pkgdir/usr/sbin"
install -Dm0644 $srcdir/ejabberd.service $pkgdir/usr/lib/systemd/system/ejabberd.service
# workaround
ln -s mod_configure.beam $pkgdir/usr/lib/ejabberd/ebin/configure.beam
}
# vim:set ts=2 sw=2 et:
|
