blob: f45eeb116432d4edc8572bfaba2ae4a53bb73ea1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
|
# $Id: PKGBUILD 115667 2014-07-14 05:32:06Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: ponsfoot <cabezon dot hashimoto at gmail dot com>
## Mozc compile option
_bldtype=Release
_zipcoderel=201406
_protobuf_ver=2.5.0
_gyp_rev=1950
_japanese_usage_dictionary_rev=10
_revision=271
_pkgbase=mozc
pkgname=fcitx-mozc
pkgdesc="Fcitx Module of A Japanese Input Method for Chromium OS, Windows, Mac and Linux (the Open Source Edition of Google Japanese Input)"
pkgver=1.15.1834.102
_patchver=${pkgver}.1
pkgrel=1
arch=('i686' 'x86_64')
url="http://code.google.com/p/mozc/"
license=('custom')
depends=('qt4' 'fcitx' 'zinnia')
makedepends=('pkg-config' 'python2' 'gtest' 'curl' 'gtk2' 'mesa' 'svn' 'ninja')
replaces=('mozc-fcitx')
conflicts=('mozc' 'mozc-server' 'mozc-utils-gui' 'mozc-fcitx')
source=(mozc::svn+http://mozc.googlecode.com/svn/trunk/src#revision=$_revision
japanese_usage_dictionary::svn+http://japanese-usage-dictionary.googlecode.com/svn/trunk#revision=$_japanese_usage_dictionary_rev
gyp::svn+http://gyp.googlecode.com/svn/trunk#revision=$_gyp_rev
http://downloads.sourceforge.net/pnsft-aur/x-ken-all-${_zipcoderel}.zip
http://downloads.sourceforge.net/pnsft-aur/jigyosyo-${_zipcoderel}.zip
http://protobuf.googlecode.com/files/protobuf-${_protobuf_ver}.tar.bz2
http://download.fcitx-im.org/fcitx-mozc/fcitx-mozc-${_patchver}.patch
http://download.fcitx-im.org/fcitx-mozc/fcitx-mozc-icon.tar.gz)
prepare() {
cd mozc
# Apply fcitx patch
rm unix/fcitx -rf
patch -Np2 -i "$srcdir/fcitx-mozc-${_patchver}.patch"
# Fix qt4 binary path
sed -i 's|(qt_dir)/bin|(qt_dir)/lib/qt4/bin|' gui/*.gyp{,i}
sed -i 's|(qt_dir_env)/bin|(qt_dir_env)/lib/qt4/bin|' gui/*.gyp{,i}
# Adjust to use python2
find . -name \*.py -type f -exec sed -i -e "1s|python.*$|python2|" {} +
find . -regex '.*\.gypi?$' -type f -exec sed -i -e "s|'python'|'python2'|g" {} +
# Copy japanese_usage_dictionary
mkdir third_party/japanese_usage_dictionary
cp -a "$srcdir"/japanese_usage_dictionary/* third_party/japanese_usage_dictionary
# Copy gyp
mkdir third_party/gyp
cp -a "${srcdir}"/gyp/* third_party/gyp
# Copy protobuf to be linked statically
mkdir third_party/protobuf
cp -rf "${srcdir}/protobuf-${_protobuf_ver}"/* third_party/protobuf
}
build() {
# Update: Fix qt4 include path too
# Fix compatibility with google-glog 0.3.3 (symbol conflict)
CFLAGS="${CFLAGS} -I/usr/include/qt4 -fvisibility=hidden"
CXXFLAGS="${CXXFLAGS} -I/usr/include/qt4 -fvisibility=hidden"
cd mozc
# Generate zip code seed
msg "Generating zip code seed..."
python2 dictionary/gen_zip_code_seed.py --zip_code="${srcdir}/x-ken-all.csv" --jigyosyo="${srcdir}/JIGYOSYO.CSV" >> data/dictionary_oss/dictionary09.txt
msg "Done."
msg "Starting make..."
_targets="server/server.gyp:mozc_server gui/gui.gyp:mozc_tool unix/fcitx/fcitx.gyp:fcitx-mozc"
QTDIR=/usr GYP_DEFINES="document_dir=/usr/share/licenses/$pkgname" python2 build_mozc.py gyp
python2 build_mozc.py build -c $_bldtype $_targets
# Extract license part of mozc
head -n 29 server/mozc_server.cc > LICENSE
}
package() {
cd mozc
install -D -m 755 out_linux/${_bldtype}/mozc_server "${pkgdir}/usr/lib/mozc/mozc_server"
install -m 755 out_linux/${_bldtype}/mozc_tool "${pkgdir}/usr/lib/mozc/mozc_tool"
install -d "${pkgdir}/usr/share/licenses/$pkgname/"
install -m 644 LICENSE data/installer/*.html "${pkgdir}/usr/share/licenses/${pkgname}/"
for mofile in out_linux/${_bldtype}/gen/unix/fcitx/po/*.mo
do
filename=`basename $mofile`
lang=${filename/.mo/}
install -D -m 644 "$mofile" "${pkgdir}/usr/share/locale/$lang/LC_MESSAGES/fcitx-mozc.mo"
done
install -D -m 755 out_linux/${_bldtype}/fcitx-mozc.so "${pkgdir}/usr/lib/fcitx/fcitx-mozc.so"
install -D -m 644 unix/fcitx/fcitx-mozc.conf "${pkgdir}/usr/share/fcitx/addon/fcitx-mozc.conf"
install -D -m 644 unix/fcitx/mozc.conf "${pkgdir}/usr/share/fcitx/inputmethod/mozc.conf"
install -d "${pkgdir}/usr/share/fcitx/mozc/icon"
install -m 644 "$srcdir/fcitx-mozc-icons/mozc.png" "${pkgdir}/usr/share/fcitx/mozc/icon/mozc.png"
install -m 644 "$srcdir/fcitx-mozc-icons/mozc-alpha_full.png" "${pkgdir}/usr/share/fcitx/mozc/icon/mozc-alpha_full.png"
install -m 644 "$srcdir/fcitx-mozc-icons/mozc-alpha_half.png" "${pkgdir}/usr/share/fcitx/mozc/icon/mozc-alpha_half.png"
install -m 644 "$srcdir/fcitx-mozc-icons/mozc-direct.png" "${pkgdir}/usr/share/fcitx/mozc/icon/mozc-direct.png"
install -m 644 "$srcdir/fcitx-mozc-icons/mozc-hiragana.png" "${pkgdir}/usr/share/fcitx/mozc/icon/mozc-hiragana.png"
install -m 644 "$srcdir/fcitx-mozc-icons/mozc-katakana_full.png" "${pkgdir}/usr/share/fcitx/mozc/icon/mozc-katakana_full.png"
install -m 644 "$srcdir/fcitx-mozc-icons/mozc-katakana_half.png" "${pkgdir}/usr/share/fcitx/mozc/icon/mozc-katakana_half.png"
install -m 644 "$srcdir/fcitx-mozc-icons/mozc-dictionary.png" "${pkgdir}/usr/share/fcitx/mozc/icon/mozc-dictionary.png"
install -m 644 "$srcdir/fcitx-mozc-icons/mozc-properties.png" "${pkgdir}/usr/share/fcitx/mozc/icon/mozc-properties.png"
install -m 644 "$srcdir/fcitx-mozc-icons/mozc-tool.png" "${pkgdir}/usr/share/fcitx/mozc/icon/mozc-tool.png"
}
sha512sums=('SKIP'
'SKIP'
'SKIP'
'bdfebfd2a72ea1e8bd5e29c7e065b4ed45c1e5bc6f43e8fbdbf454f24fdf7d44b4f10f8a8f0ca5b6e433bb87877e77a3998a6b25ad9f904f2529d0d2e0ae4b76'
'bbfd5a48426bfa4a1d438d6d640ceb76174aac4d503dc9de64e6cd1d72c5e081588a2893ba7a558444a38c0f6a132acb0e5a3aed61ad79744efb3aa9dbb6c523'
'5994b3669808b82fef5c860ecad36358c0767f84acac877e7bfcf722e59d972835a955714149bdd4158fbd1328a51d01397a563991d26475351ee72be48142ee'
'7a5bcedc8c3174fb65bdfd2126abae0f7432bc5b10dfdce7cd9703bdeac4a5652cc3be59b2a6829184a1b4e0199bf9606db79c2cef7858c2ccc6a5a367b229c6'
'5507c637e5a65c44ccf6e32118b6d16647ece865171b9a77dd3c78e6790fbd97e6b219e68d2e27750e22074eb536bccf8d553c295d939066b72994b86b2f251a')
|
