blob: cc332ae86e7fa819fec1c57b48ca7606e821e4b1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 111817 2014-05-25 09:22:34Z jlichtblau $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Roman Kyrylych <roman@archlinux.org>
# Contributor: Johannes Sjolund <j.sjolund@gmail.com>
pkgname=gnome-commander
pkgver=1.4.2
pkgrel=1
pkgdesc='Graphical two-pane filemanager for Gnome'
arch=('i686' 'x86_64')
url='http://gcmd.github.io/'
license=('GPL')
depends=('libgnomeui' 'gnome-vfs' 'gconf' 'python2' 'libsm' 'libunique')
makedepends=('perl-xml-parser' 'gnome-doc-utils' 'intltool')
install=$pkgname.install
changelog=$pkgname.changelog
source=(ftp://ftp.gnome.org/pub/GNOME/sources/gnome-commander/1.4/$pkgname-$pkgver.tar.xz)
sha256sums=('8f47ac8428086406536c45b53cbf23b734322f2a557d91698cdeb2bd296f3029')
build() {
cd "$pkgname-$pkgver"
# Python 2 fix
for f in doc/*/gnome-commander.xml; do
sed -i 's:env python:env python2:' "$f"
done
./configure --prefix=/usr --libdir=/usr/lib --sysconfdir=/etc \
--localstatedir=/var --disable-scrollkeeper --enable-python
make
}
package() {
cd "$pkgname-$pkgver"
make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="$pkgdir" install
install -d "$pkgdir/usr/share/gconf/schemas"
gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/$pkgname.schemas" \
--domain "$pkgname" "$pkgdir/etc/gconf/schemas/"*.schemas
rm -rf "$pkgdir/etc/gconf/schemas/"
}
# vim:set ts=2 sw=2 et:
|
