blob: 20c933ec776609fe4b2f6f50c7ce208f300dfcb0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 48001 2011-05-26 23:17:43Z jconder $
# Maintainer: Jonathan Conder <jonno.conder@gmail.com>
pkgname=gnome-packagekit
pkgver=3.0.2
pkgrel=1
pkgdesc='Collection of graphical tools for PackageKit to be used in the GNOME desktop'
arch=('i686' 'x86_64')
url='http://www.packagekit.org/'
license=('GPL')
depends=('dconf' 'desktop-file-utils' 'gnome-menus' 'gtk3'
'hicolor-icon-theme' 'libnotify' 'packagekit')
makedepends=('gconf' 'gtk-doc' 'gnome-common' 'intltool' 'libcanberra' 'upower')
optdepends=('gnome-settings-daemon-updates: update and message notifications')
options=('!emptydirs' '!libtool')
install="$pkgname.install"
source=("http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2"
'arch.patch')
sha256sums=('faaae52d839a66d0bcb7d7cf97ef62d11bccf558e6aa9fdb0dbc8d61dbaf714f'
'9c809ac3c8bbf870442e7bc4123c70b144930a287b28626be1b8bae95edf71ac')
build() {
cd "$srcdir/$pkgname-$pkgver"
patch -Np1 -i "$srcdir/arch.patch"
sed -i 's@python@python2@' 'python/enum-convertor.py'
export PYTHON=/usr/bin/python2
# TODO: remove gnome-common dependency and switch back to configure
gnome-autogen.sh --prefix=/usr \
--sysconfdir=/etc \
--disable-gtk-doc \
--disable-schemas-compile \
--disable-scrollkeeper
make -s
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make -s DESTDIR="$pkgdir" install
rm -rf "$pkgdir/usr/lib/gnome-settings-daemon-3.0/gtk-modules"
}
|
