blob: 6c83652a78949715df2427311ceeff8ab4314d7b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id:
# Maintainer : Martin Wimpress <code@flexion.org>
# Contributor: Sauyon Lee <arch@sauyon.com>
pkgname=godep
pkgver=94.20140524
pkgrel=1
epoch=1
pkgdesc="Dependency tool for go"
arch=('i686' 'x86_64')
url="http://github.com/tools/godep"
license=('BSD')
depends=('glibc')
makedepends=('git' 'go' 'mercurial')
source=("${pkgname}::git+https://github.com/tools/godep#commit=983ff9241cead0f7e6ad0ae4a92b335c33ade8a2")
md5sums=('SKIP')
pkgver() {
cd "${srcdir}/${pkgname}"
printf "%s.%s" "$(git rev-list --count HEAD)" "$(git log -1 --format=%cd --date=short | tr -d -)"
}
prepare() {
export GOPATH="${srcdir}"
go get code.google.com/p/go.tools/go/vcs
go get github.com/kr/fs
}
build() {
cd "${srcdir}/${pkgname}"
GOPATH="${srcdir}" go build
}
package() {
cd "${srcdir}/${pkgname}"
install -Dm755 "${pkgname}" "${pkgdir}/usr/bin/godep"
install -Dm644 License "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|