blob: 774da33379acf18c07d99dcefff996021b2280e5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# $Id: PKGBUILD 99786 2013-10-30 23:42:41Z allan $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Thomas Mudrunka <harvie@@email..cz>
pkgname=gpointing-device-settings
pkgver=1.5.1
pkgrel=4
pkgdesc="GUI tool for setting pointing device such as TrackPoint or Touchpad"
arch=('i686' 'x86_64')
license=('GPL')
url="http://live.gnome.org/GPointingDeviceSettings"
depends=('gtk2' 'gconf')
makedepends=('gnome-settings-daemon' 'intltool')
source=("http://keihanna.dl.sourceforge.jp/gsynaptics/45812/${pkgname}-${pkgver}.tar.gz")
md5sums=('1d1491473df8eabca3c15c997a975d7f')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
# Enable deprecations
sed -i -e '/DISABLE_DEPRECATED/d' -e 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/' configure.ac
# Disable GSD plugin (won't build with GSD 3.8)
sed -i 's/ gnome-settings-daemon-plugins//' modules/Makefile.am
autoreconf -fi
./configure --prefix=/usr --sysconfdir=/etc \
--disable-static --disable-schemas-install \
--with-gconf-schema-file-dir=/usr/share/gconf/schemas
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR=${pkgdir} install
# Remove GConf schema (used by GSD plugin)
rm -r "${pkgdir}/usr/share/gconf"
}
|
