blob: 47499b1a30656b649580dccda2f3328a3f3b503c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 71956 2012-06-04 07:44:12Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: dibblethewrecker dibblethewrecker.at.jiwe.dot.org
# Contributor: William Rea <sillywilly@gmail.com>
pkgname=gpsbabel
pkgver=1.4.3
pkgrel=1
pkgdesc="Reads, writes, and manipulates GPS waypoints in a variety of formats"
arch=('i686' 'x86_64')
url="http://www.gpsbabel.org"
license=('GPL')
depends=('libusb-compat' 'expat')
makedepends=('fop' 'qt' 'libxml2' 'libxslt' 'gtk2' 'lcms2' 'qtwebkit' 'openjdk6')
optdepends=('qt' 'qtwebkit')
options=('docs')
source=("gpsbabel-$pkgver.tar.gz::http://archlinux-stuff.googlecode.com/files/gpsbabel-$pkgver.tar.gz"
"gpsbabel.desktop::http://pkgs.fedoraproject.org/gitweb/?p=gpsbabel.git;a=blob_plain;f=gpsbabel.desktop;hb=HEAD")
md5sums=('916f7e124f6df911a24e1ea323e9c529'
'7bdbd243e29a8831842d31c079f04c45')
build() {
cd $srcdir/gpsbabel-$pkgver
./configure --prefix=/usr
make
make doc
(cd gui && qmake && make)
}
package() {
cd $srcdir/gpsbabel-$pkgver
make DESTDIR=$pkgdir install
# GUI
install -Dm755 gui/objects/gpsbabelfe-bin ${pkgdir}/usr/bin/gpsbabelfe-bin
install -Dm644 gui/images/appicon.png $pkgdir/usr/share/pixmaps/gpsbabel.png
install -Dm644 $srcdir/gpsbabel.desktop $pkgdir/usr/share/applications/gpsbabel.desktop
# Header install
mkdir -p $pkgdir/usr/include/gpsbabel
cp {defs.h,queue.h,gbtypes.h,filterdefs.h,cet.h,cet_util.h,garmin_tables.h} \
$pkgdir/usr/include/gpsbabel
# Doc install
mkdir -p $pkgdir/usr/share/doc/$pkgname
cp -r $srcdir/babelweb/* $pkgdir/usr/share/doc/$pkgname/
cp README* $pkgdir/usr/share/doc/$pkgname/
}
|
