blob: f74265df9be21dd6982570485b5cf80b8785484b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Daniel Micay <danielmicay@gmail.com>
# Contributor: Arch Haskell Team <>
# Contributor: Lex Black <autumn-wind at web dot de>
_hkgname=base64-bytestring
pkgname=haskell-base64-bytestring
pkgver=1.0.0.1
pkgrel=2
pkgdesc="Fast base64 encoding and deconding for ByteStrings"
url="https://github.com/bos/base64-bytestring"
license=(custom:BSD3)
arch=('i686' 'x86_64')
makedepends=('ghc')
depends=('haskell-bytestring')
source=("http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
install="$pkgname.install"
sha256sums=('ab25abf4b00a2f52b270bc3ed43f1d59f16c8eec9d7dffb14df1e9265b233b50')
build() {
cd "$srcdir/$_hkgname-$pkgver"
runhaskell Setup configure -O -p --enable-split-objs --enable-shared \
--prefix=/usr --docdir=/usr/share/doc/$pkgname \
--libsubdir=\$compiler/site-local/\$pkgid
runhaskell Setup build
runhaskell Setup haddock
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}
package() {
cd "$srcdir/$_hkgname-$pkgver"
install -Dm744 register.sh "$pkgdir/usr/share/haskell/$pkgname/register.sh"
install -m744 unregister.sh "$pkgdir/usr/share/haskell/$pkgname/unregister.sh"
install -d -m755 "$pkgdir/usr/share/doc/ghc/html/libraries"
ln -s /usr/share/doc/$pkgname/html "$pkgdir/usr/share/doc/ghc/html/libraries/$_hkgname"
runhaskell Setup copy --destdir="$pkgdir"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
rm -f "$pkgdir/usr/share/doc/$pkgname/LICENSE"
}
|
