blob: b6099a70de5adeaf869326f74ae45201a67a7592 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Daniel Micay <danielmicay@gmail.com>
# Contributor: Arch Haskell Team <>
# Contributor: Lex Black <autumn-wind at web dot de>
_hkgname=pandoc-types
pkgname=haskell-pandoc-types
pkgver=1.12.1
pkgrel=1
pkgdesc="Types for representing a structured document"
url="http://johnmacfarlane.net/pandoc"
license=("GPL")
arch=('i686' 'x86_64')
makedepends=('ghc')
depends=('haskell-containers' 'haskell-syb' 'haskell-aeson')
source=("http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
install=$pkgname.install
sha256sums=('726df226da9cc55b986380d64bb362b66238f41fdef4c56b027d97a7fc3a163f')
build() {
cd "$srcdir/$_hkgname-$pkgver"
runhaskell Setup configure -O --enable-split-objs --enable-shared \
--prefix=/usr --docdir=/usr/share/doc/$pkgname \
--libsubdir=\$compiler/site-local/\$pkgid
runhaskell Setup build
runhaskell Setup haddock
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}
package() {
cd "$srcdir/$_hkgname-$pkgver"
install -D -m744 register.sh "$pkgdir/usr/share/haskell/$pkgname/register.sh"
install -m744 unregister.sh "$pkgdir/usr/share/haskell/$pkgname/unregister.sh"
install -d -m755 "$pkgdir/usr/share/doc/ghc/html/libraries"
ln -s /usr/share/doc/$pkgname/html "$pkgdir/usr/share/doc/ghc/html/libraries/$_hkgname"
runhaskell Setup copy --destdir="$pkgdir"
rm -f "$pkgdir/usr/share/doc/$pkgname/COPYING"
}
|
