blob: 7be6b094c95115f04866d58d8f040d9e7df5e9e8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Daniel Micay <danielmicay@gmail.com>
# Contributor: Arch Haskell Team <>
# Contributor: Lex Black <autumn-wind at web dot de>
pkgname=haskell-texmath
_hkgname=texmath
pkgver=0.6.1.3
pkgrel=1
pkgdesc="Conversion of LaTeX math formulas to MathML."
url="https://github.com/jgm/texmath"
license=("GPL")
arch=('i686' 'x86_64')
makedepends=('ghc')
depends=(haskell-containers haskell-parsec haskell-syb haskell-xml)
source=("http://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-${pkgver}.tar.gz")
install=$pkgname.install
md5sums=('6737a06392f51886e8b1ca8aa6dc2168')
build() {
cd "$srcdir/$_hkgname-$pkgver"
runhaskell Setup configure -O -p --enable-split-objs --enable-shared \
--prefix=/usr --docdir=/usr/share/doc/$pkgname \
--libsubdir=\$compiler/site-local/\$pkgid
runhaskell Setup build
runhaskell Setup haddock
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}
package() {
cd "$srcdir/$_hkgname-$pkgver"
install -Dm744 register.sh "$pkgdir/usr/share/haskell/$pkgname/register.sh"
install -m744 unregister.sh "$pkgdir/usr/share/haskell/$pkgname/unregister.sh"
install -dm755 "$pkgdir/usr/share/doc/ghc/html/libraries"
ln -s /usr/share/doc/$pkgname/html "$pkgdir/usr/share/doc/ghc/html/libraries/$_hkgname"
runhaskell Setup copy --destdir="$pkgdir"
install -Dm644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
rm -f "$pkgdir/usr/share/doc/$pkgname/LICENSE"
}
|
