blob: 5efdf577ce4299b8feb79065a9be58baf4ddd84e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# $Id: PKGBUILD 113261 2014-06-16 19:17:35Z ttoepper $
# Maintainer: Thorsten Töpper <atsutane-tu@freethoughts.de>
pkgname=i3-wm
_pkgsourcename=i3
pkgver=4.8
pkgrel=2
pkgdesc='An improved dynamic tiling window manager'
arch=('i686' 'x86_64')
url='http://i3wm.org/'
license=('BSD')
replaces=('i3' 'i3bar')
groups=('i3')
depends=('xcb-util-cursor' 'xcb-util-keysyms' 'xcb-util-wm' 'libev' 'yajl'
'startup-notification' 'pango')
makedepends=('bison' 'flex')
optdepends=('dmenu: As menu.'
'i3lock: For locking your screen.'
'i3status: To display systeminformation with a bar.'
'perl-anyevent-i3: Features like saving the layout.'
'perl-json-xs: Features like saving the layout.')
options=('docs' '!strip')
source=("http://i3wm.org/downloads/${_pkgsourcename}-${pkgver}.tar.bz2"
"http://i3wm.org/downloads/${_pkgsourcename}-${pkgver}.tar.bz2.asc")
md5sums=('4151e8e81fdc78b32a7cb953f67e3bef'
'SKIP')
build() {
cd "$srcdir/$_pkgsourcename-$pkgver"
# In order to avoid problems with bison use only a single process
MAKEFLAGS="-j1"
make
}
package() {
cd "$srcdir/$_pkgsourcename-$pkgver"
make DESTDIR="$pkgdir/" install
install -Dm644 man/i3.1 \
${pkgdir}/usr/share/man/man1/i3.1
install -Dm644 man/i3bar.1 \
${pkgdir}/usr/share/man/man1/i3bar.1
install -Dm644 man/i3-config-wizard.1 \
${pkgdir}/usr/share/man/man1/i3-config-wizard.1
install -Dm644 man/i3-input.1 \
${pkgdir}/usr/share/man/man1/i3-input.1
install -Dm644 man/i3-msg.1 \
${pkgdir}/usr/share/man/man1/i3-msg.1
install -Dm644 man/i3-migrate-config-to-v4.1 \
${pkgdir}/usr/share/man/man1/i3-migrate-config-to-v4.1
install -Dm644 man/i3-nagbar.1 \
${pkgdir}/usr/share/man/man1/i3-nagbar.1
install -Dm644 man/i3-dmenu-desktop.1 \
${pkgdir}/usr/share/man/man1/i3-dmenu-desktop.1
install -Dm644 man/i3-dump-log.1 \
${pkgdir}/usr/share/man/man1/i3-dump-log.1
install -Dm644 man/i3-sensible-editor.1 \
${pkgdir}/usr/share/man/man1/i3-sensible-editor.1
install -Dm644 man/i3-sensible-pager.1 \
${pkgdir}/usr/share/man/man1/i3-sensible-pager.1
install -Dm644 man/i3-sensible-terminal.1 \
${pkgdir}/usr/share/man/man1/i3-sensible-terminal.1
install -Dm644 LICENSE \
${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
make clean
}
# vim:set ts=2 sw=2 et:
|
