blob: 08aea8acced833e0073caaca0d9117f599b6743b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
|
# $Id: PKGBUILD 110240 2014-04-27 16:48:38Z heftig $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
pkgname=libgexiv2
pkgver=0.10.1
pkgrel=1
pkgdesc='GObject-based wrapper around the Exiv2 library'
url='https://wiki.gnome.org/Projects/gexiv2'
arch=('x86_64' 'i686')
license=('GPL2')
depends=('exiv2' 'glib2')
makedepends=('python-gobject' 'python2-gobject')
source=("http://ftp.gnome.org/pub/gnome/sources/${pkgname/lib/}/${pkgver%.*}/${pkgname/lib/}-$pkgver.tar.xz")
sha256sums=('7675752a59c2f091560be1f39514ef492ec705b9fdea5f52281672e6b3eba2c7')
build() {
cd "${pkgname/lib/}-$pkgver"
# In order for the build process to include any python-related files,
# 'import gi; print(gi._overridesdir)' must work with either python or
# python2. The gi module is provided by python-gobject and python2-gobject.
./configure --prefix=/usr --enable-introspection
make
}
package() {
make -C "${pkgname/lib/}-$pkgver" DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|
