blob: ac56d3e62e2589f982e0ffefbab03259ae68f360 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 112507 2014-06-02 21:55:03Z foutrelis $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
pkgname=libmemcached
pkgver=1.0.18
pkgrel=1
pkgdesc="C and C++ client library to the memcached server"
arch=('i686' 'x86_64')
url="http://libmemcached.org/"
license=('GPL')
depends=('glibc' 'libsasl' 'libevent')
makedepends=('perl' 'memcached' 'python-sphinx')
source=(http://launchpad.net/$pkgname/1.0/$pkgver/+download/$pkgname-$pkgver.tar.gz
libmemcached-fix-linking-with-libpthread.patch)
sha256sums=('e22c0bb032fde08f53de9ffbc5a128233041d9f33b5de022c0978a2149885f82'
'02cd903ed217ef6d023bccefecb8d599ffab9b800a4f1a4e0124f4d71888d0dc')
prepare() {
cd "$srcdir/$pkgname-$pkgver"
# Fix linking against libpthread (patch from Fedora)
# https://bugzilla.redhat.com/show_bug.cgi?id=1037707
# https://bugs.launchpad.net/libmemcached/+bug/1281907
patch -Np1 -i ../libmemcached-fix-linking-with-libpthread.patch
}
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure --prefix=/usr
make
}
check() {
cd "$srcdir/$pkgname-$pkgver"
#make -k check
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|
