blob: 01d8ff1bea27ff0bffd97776add131734ed28234 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 81120 2012-12-12 00:49:31Z eric $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Dwayne Bent <dbb.1@liqd.org>
# Contributor: Paul-Sebastian Manole <brokenthorn@gmail.com>
pkgbase=luasec
pkgname=(lua-sec lua51-sec)
pkgver=0.4.1
pkgrel=1
pkgdesc='Lua bindings for OpenSSL library to provide TLS/SSL communication.'
arch=('i686' 'x86_64')
url='http://luasec.luaforge.net/'
license=('MIT')
makedepends=('openssl' 'lua' 'lua-socket' 'lua51' 'lua51-socket')
conflicts=('luasec')
replaces=('luasec')
source=("http://www.inf.puc-rio.br/~brunoos/luasec/download/$pkgbase-$pkgver.tar.gz")
md5sums=('b8a5fde3b3fdb6174f54cd51d7f53e12')
build() {
cp -a $pkgbase-$pkgver $pkgbase-$pkgver-51
msg2 'Building with lua 5.2'
cd $pkgbase-$pkgver
make linux
msg2 'Building with lua 5.1'
cd ../$pkgbase-$pkgver-51
make INCDIR=-I/usr/include/lua5.1 linux
}
package_lua-sec() {
depends=('openssl' 'lua' 'lua-socket')
install -dm755 "$pkgdir/usr/lib/lua/5.2"
cd $pkgbase-$pkgver
make LUACPATH="$pkgdir/usr/lib/lua/5.2" LUAPATH="$pkgdir/usr/share/lua/5.2" install
install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
package_lua51-sec() {
depends=('openssl' 'lua51' 'lua51-socket')
install -dm755 "$pkgdir/usr/lib/lua/5.1"
cd $pkgbase-$pkgver-51
make LUACPATH="$pkgdir/usr/lib/lua/5.1" LUAPATH="$pkgdir/usr/share/lua/5.1" install
install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=4 sw=4 et:
|
