blob: 9d4effbc34029fc016600dcbe4b43166ab565ff3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
|
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: ponsfoot <cabezon dot hashimoto at gmail dot com>
pkgbase=marisa
pkgname=('marisa' 'perl-marisa' 'python2-marisa' 'ruby-marisa')
pkgver=0.2.4
pkgrel=2
arch=('i686' 'x86_64')
url="https://code.google.com/p/marisa-trie/"
license=('BSD' 'LGPL')
options=(!libtool)
makedepends=('python2' 'ruby' 'perl')
changelog=ChangeLog
source=(https://marisa-trie.googlecode.com/files/$pkgbase-$pkgver.tar.gz)
sha1sums=('fb0ed7d993e84dff32ec456a79bd36a00022629d')
build() {
cd "${pkgname}-${pkgver}"
./configure --prefix=/usr --disable-static \
# --enable-popcnt
# --enable-sse2
# --enable-sse3
# --enable-ssse3
# --enable-sse4.1
# --enable-sse4.2
# --enable-sse4
# --enable-sse4a
sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
make
# Perl bindings
cd "${srcdir}/${pkgbase}-${pkgver}/bindings/perl"
perl Makefile.PL \
INC="-I${srcdir}/${pkgbase}-${pkgver}/lib" \
LIBS="-L${srcdir}/${pkgbase}-${pkgver}/lib/.libs"
make
# Python bindings
cd "${srcdir}/${pkgbase}-${pkgver}/bindings/python"
python2 setup.py build_ext \
--include-dirs="${srcdir}/${pkgbase}-${pkgver}/lib" \
--library-dirs="${srcdir}/${pkgbase}-${pkgver}/lib/.libs"
python2 setup.py build
# Ruby bindings
cd "${srcdir}/${pkgbase}-${pkgver}/bindings/ruby"
ruby extconf.rb \
--with-opt-include="${srcdir}/${pkgbase}-${pkgver}/lib" \
--with-opt-lib="${srcdir}/${pkgbase}-${pkgver}/lib/.libs" \
--vendor
make
}
package_marisa() {
pkgdesc="Static and space-efficient trie data structure library"
depends=('gcc-libs')
cd "${pkgbase}-${pkgver}"
make DESTDIR="$pkgdir" install
install -d "${pkgdir}/usr/share/doc/${pkgbase}-${pkgver}"
install -m 644 docs/* README "${pkgdir}/usr/share/doc/${pkgbase}-${pkgver}/"
install -d "${pkgdir}/usr/share/licenses/$pkgname"
install -m 644 AUTHORS COPYING "${pkgdir}/usr/share/licenses/$pkgname/"
}
package_perl-marisa() {
pkgdesc="Perl language binding for marisa"
depends=('perl' 'marisa')
cd "${pkgbase}-${pkgver}/bindings/perl"
make DESTDIR="$pkgdir" install
cd ../..
install -d "${pkgdir}/usr/share/licenses/$pkgname"
install -m 644 AUTHORS COPYING "${pkgdir}/usr/share/licenses/$pkgname/"
}
package_python2-marisa() {
pkgdesc="Python 2.x language binding for marisa"
depends=('python2' 'marisa')
cd "${pkgbase}-${pkgver}/bindings/python"
python2 setup.py install --root="$pkgdir"
cd ../..
install -d "${pkgdir}/usr/share/licenses/$pkgname"
install -m 644 AUTHORS COPYING "${pkgdir}/usr/share/licenses/$pkgname/"
}
package_ruby-marisa() {
pkgdesc="Ruby language binding for marisa"
depends=('ruby' 'marisa')
cd "${pkgbase}-${pkgver}/bindings/ruby"
_hdrdir=`pkg-config --variable=rubyhdrdir ruby-2.0`
_arch=`pkg-config --variable=arch ruby-2.0`
make DESTDIR="$pkgdir" install \
hdrdir="$_hdrdir" \
arch_hdrdir="${_hdrdir}/${_arch}" \
rubyhdrdir="$_hdrdir"
cd ../..
install -d "${pkgdir}/usr/share/licenses/$pkgname"
install -m 644 AUTHORS COPYING "${pkgdir}/usr/share/licenses/$pkgname/"
}
|
