blob: 386fdcf3e661a88110947f7244f714d3bd8e1c09 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer : Martin Wimpress <code@flexion.org>
pkgname=mate-applets
pkgver=1.8.0
pkgrel=1
pkgdesc="Applets for MATE panel"
arch=('i686' 'x86_64')
url="http://mate-desktop.org"
license=('GPL')
depends=('gtksourceview2' 'gucharmap' 'mate-panel' 'python2-dbus'
'python2-gobject' 'upower')
makedepends=('docbook2x' 'docbook-xsl' 'mate-common' 'networkmanager'
'perl-xml-parser' 'yelp-tools')
optdepends=('yelp: for reading MATE help documents')
options=('!emptydirs')
groups=('mate-extra')
source=("http://pub.mate-desktop.org/releases/1.8/${pkgname}-${pkgver}.tar.xz")
sha1sums=('c9e7ac6f9cc6b6ebd77720b056a3a81536b92419')
install=${pkgname}.install
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i 's/env python/env python2/' invest-applet/invest/{chart.py,invest-applet.py,mate-invest-chart}
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
PYTHON=/usr/bin/python2 ./configure \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/${pkgname} \
--enable-polkit \
--enable-networkmanager \
--enable-ipv6 \
--disable-static
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
