blob: 88bf488ead9dbb8d40bff99fc847f11562dc8bcf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer : Martin Wimpress <code@flexion.org>
pkgname=mate-desktop
pkgver=1.8.1
pkgrel=1
pkgdesc="Library with common API for various MATE modules"
url="http://mate-desktop.org"
arch=('i686' 'x86_64')
license=(GPL LGPL)
depends=('dconf' 'gtk2' 'hicolor-icon-theme' 'libunique' 'python2'
'startup-notification' 'ttf-dejavu')
makedepends=('mate-common' 'perl-xml-parser' 'yelp-tools')
optdepends=('lightdm-gtk2-greeter: A lightweight display manager'
'onboard: On-screen keyboard useful for mobility impaired users'
'orca: Screen reader for blind or visually impaired individuals'
'yelp: for reading MATE help documents')
groups=('mate')
source=("http://pub.mate-desktop.org/releases/1.8/${pkgname}-${pkgver}.tar.xz")
sha1sums=('e3e92eec0cf0443d6a0ca18ad2f88b2ddd54f833')
install=${pkgname}.install
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i 's|\/usr\/bin\/python|\/usr\/bin\/env python2|' tools/mpaste
}
build() {
# See the following for '--disable-desktop-docs' justification
# - https://github.com/mate-desktop/mate-desktop/issues/68
cd "${srcdir}/${pkgname}-${pkgver}"
PYTHON=/usr/bin/python2 ./configure \
--prefix=/usr \
--with-gtk=2.0 \
--enable-mpaste \
--disable-static \
--disable-schemas-compile \
--disable-desktop-docs \
--enable-gtk-doc
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
