blob: 1a8ecd1dac51ef68165357acbc7a744d2660688b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# $Id: PKGBUILD 45343 2011-04-20 13:49:48Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Larry Hajali <larryhaja [at] gmail [dot] com>
pkgname=megaglest
pkgver=3.5.0
pkgrel=1
pkgdesc="Fork of Glest, a 3D real-time strategy game in a fantastic world."
arch=('i686' 'x86_64')
url="http://sourceforge.net/projects/megaglest/"
license=('GPL2')
depends=('curl' 'megaglest-data' 'xerces-c' 'sdl' 'libvorbis' 'openal' 'mesa' 'lua' 'icu')
makedepends=('ftjam' 'p7zip' 'wxgtk' 'cmake')
source=("http://downloads.sourceforge.net/project/${pkgname}/current_release/${pkgname}-source-${pkgver}.tar.bz2"
"http://downloads.sourceforge.net/project/${pkgname}/current_release/megaglest-data-${pkgver}.7z"
"megaglest.png"
"megaglest.desktop"
"megaglest.sh")
md5sums=('5c84966ee6657274eeb5a28ce8b702c0'
'4405134d91d8303e9485de42ffc53e09'
'5622ce716033d9afb62a3291b47844ed'
'97dc7ea865efbea5daaf300207dad518'
'e3d6abbe79263d2fa5edb0bcbcf8755a')
build() {
cd ${srcdir}/${pkgname}-source-${pkgver}/
7z x -y ${srcdir}/megaglest-data-${pkgver}.7z
[[ -d build ]] && rm -r build
mkdir build && cd build
cmake .. \
-DWANT_SVN_STAMP=OFF \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release # set =Debug for debugging version
make
}
package() {
cd ${srcdir}/${pkgname}-source-${pkgver}/
# Megaglest doesn't have a nice installer. Let's package it ourselves.
# Damnit, upstream.
install -d -m 0755 "${pkgdir}"/usr/{bin,share/${pkgname}}
install -m 0755 "${srcdir}"/$pkgname.sh "${pkgdir}"/usr/bin/$pkgname
install -m 0755 mk/linux/megaglest.bin "${pkgdir}"/usr/share/${pkgname}/$pkgname
install -m 0755 mk/linux/megaglest_configurator "${pkgdir}"/usr/bin/megaglest_configurator
install -m 0755 mk/linux/megaglest_editor "${pkgdir}"/usr/bin/megaglest_editor
install -m 0644 glest.ini glestkeys.ini servers.ini "${pkgdir}"/usr/share/$pkgname
install -D -m 0644 "${srcdir}"/${pkgname}.desktop "${pkgdir}"/usr/share/applications/${pkgname}.desktop
install -D -m 0644 "${srcdir}"/${pkgname}.png "${pkgdir}"/usr/share/pixmaps/${pkgname}.png
}
# vim: sw=2:ts=2 et:
|
