blob: 0707f8821486503cfe70d36ddcc918d8dfb3cc7c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 108698 2014-04-01 14:35:40Z anatolik $
# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>
pkgname=mldonkey
pkgver=3.1.5
pkgrel=1
pkgdesc='A multi-network P2P client'
arch=(i686 x86_64)
url='http://mldonkey.sourceforge.net/'
license=(GPL)
depends=(file gd miniupnpc libnatpmp)
makedepends=(lablgtk2 librsvg ocaml)
optdepends=('librsvg: GUI support'
'gtk2: GUI support')
backup=(etc/conf.d/mldonkey)
install=mldonkey.install
source=(http://downloads.sourceforge.net/sourceforge/mldonkey/$pkgname-$pkgver.tar.bz2
mldonkey.conf
mldonkey.service
mldonkey.tmpfiles)
sha256sums=('74f9d4bcc72356aa28d0812767ef5b9daa03efc5d1ddabf56447dc04969911cb'
'f1d9401cefd591662d49011c53fdb2788755a6f745a963e46d8037b990edeb6a'
'778cebe8edcffd63db3594054c2daa62ce571644a96ad235b8c95470b55c0415'
'45f45d2a3c064d5bbc0b6b9b70fa3497ed47cfecdd1ec52e175311f48eaa89dc')
build() {
cd mldonkey-$pkgver
./configure --prefix=/usr --enable-gui=newgui2 --enable-upnp-natpmp
make
}
package() {
cd mldonkey-$pkgver
make DESTDIR="$pkgdir" install
install -Dm644 icons/rsvg/type_source_normal.svg "$pkgdir"/usr/share/icons/mldonkey.svg
install -Dm644 distrib/mldonkey.desktop "$pkgdir"/usr/share/applications/mldonkey.desktop
install -Dm644 "$srcdir"/mldonkey.conf "$pkgdir"/etc/conf.d/mldonkey
install -Dm644 "$srcdir"/mldonkey.service "$pkgdir"/usr/lib/systemd/system/mldonkey.service
install -Dm644 "$srcdir"/mldonkey.tmpfiles "$pkgdir"/usr/lib/tmpfiles.d/mldonkey.conf
}
|
