blob: a28dcf602a200eefdff51282bb73768f54c76ca7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 109765 2014-04-18 14:38:46Z bpiotrowski $
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Eivind Uggedal <eivind@uggedal.com>
pkgname=mpv
pkgver=0.3.8
pkgrel=1
pkgdesc='Video player based on MPlayer/mplayer2'
arch=('i686' 'x86_64')
license=('GPL')
url='http://mpv.io'
depends=(
'portaudio' 'ffmpeg' 'lcms2' 'libdvdread' 'libcdio-paranoia' 'libquvi' 'libgl'
'libxinerama' 'mpg123' 'libxv' 'libxkbcommon' 'libva' 'lirc-utils' 'wayland'
'desktop-file-utils' 'hicolor-icon-theme' 'xdg-utils' 'lua' 'libdvdnav'
)
makedepends=('mesa' 'python-docutils' 'ladspa')
options=('!emptydirs' '!buildflags')
install=mpv.install
source=(https://github.com/mpv-player/$pkgname/archive/v$pkgver.tar.gz)
md5sums=('f7fc14f52c1958f6b603245b0595efa9')
prepare() {
cd $pkgname-$pkgver
./bootstrap.py
}
build() {
cd $pkgname-$pkgver
./waf configure --prefix=/usr \
--confdir=/etc/mpv \
--enable-joystick
./waf build
}
package() {
cd $pkgname-$pkgver
./waf install --destdir="$pkgdir"
install -d "$pkgdir"/usr/share/doc/mpv/examples
install -m644 etc/{input,example}.conf \
"$pkgdir"/usr/share/doc/mpv/examples
install -m644 DOCS/{encoding.rst,tech-overview.txt} \
"$pkgdir"/usr/share/doc/mpv
}
|
