blob: 3ff6e2037d3d61abf2b1a2ef4aeba7631b8225b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# $Id: PKGBUILD 113644 2014-06-26 18:21:14Z bpiotrowski $
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Eivind Uggedal <eivind@uggedal.com>
pkgname=mpv
pkgver=0.4.0
pkgrel=2
pkgdesc='Video player based on MPlayer/mplayer2'
arch=('i686' 'x86_64')
license=('GPL')
url='http://mpv.io'
depends=(
'ffmpeg' 'lcms2' 'libdvdread' 'libcdio-paranoia' 'libquvi' 'libgl' 'enca'
'libxinerama' 'mpg123' 'libxv' 'libxkbcommon' 'libva' 'lirc-utils' 'wayland'
'desktop-file-utils' 'hicolor-icon-theme' 'xdg-utils' 'lua' 'libdvdnav'
'libguess'
)
makedepends=('mesa' 'python-docutils' 'ladspa')
options=('!emptydirs' '!buildflags')
install=mpv.install
source=(https://github.com/mpv-player/$pkgname/archive/v$pkgver.tar.gz)
md5sums=('6b1ec7e8e3a2bcb5af68d62cea4577ba')
prepare() {
cd $pkgname-$pkgver
./bootstrap.py
}
build() {
cd $pkgname-$pkgver
./waf configure --prefix=/usr \
--confdir=/etc/mpv \
--enable-joystick \
--enable-zsh-comp \
--enable-libmpv-shared \
--enable-cdda
./waf build
}
package() {
cd $pkgname-$pkgver
./waf install --destdir="$pkgdir"
install -d "$pkgdir"/usr/share/doc/mpv/examples
install -m644 etc/{input,example}.conf \
"$pkgdir"/usr/share/doc/mpv/examples
install -m644 DOCS/{encoding.rst,tech-overview.txt} \
"$pkgdir"/usr/share/doc/mpv
}
|
