blob: 2c866dea61d0cb6294f5d09f44331266784a264a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id: PKGBUILD 99077 2013-10-24 08:16:35Z bpiotrowski $
# Maintainer: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Eivind Uggedal <eivind@uggedal.com>
pkgname=mpv
pkgver=0.2.1
pkgrel=1
pkgdesc='Video player based on MPlayer/mplayer2'
arch=('i686' 'x86_64')
license=('GPL')
url='http://mpv.io'
depends=(
'portaudio' 'ffmpeg' 'lcms2' 'libdvdread' 'libcdio-paranoia' 'libxinerama'
'libquvi' 'mpg123' 'libxv' 'libxkbcommon' 'libva' 'lirc-utils'
'desktop-file-utils' 'hicolor-icon-theme' 'xdg-utils'
)
makedepends=('mesa' 'python-docutils')
options=(!emptydirs)
install=mpv.install
source=("https://github.com/mpv-player/$pkgname/archive/v$pkgver.tar.gz")
md5sums=('4e7c8823354f97753f0cbe17c61ec211')
build() {
unset CFLAGS
unset LDFLAGS
cd $pkgname-$pkgver
./configure --prefix=/usr \
--confdir=/etc/mpv \
--disable-lircc \
--disable-joystick \
--disable-radio \
--disable-radio-capture \
--disable-radio-v4l2 \
--disable-rpath \
--disable-libbs2b \
--disable-direct3d \
--disable-corevideo \
--disable-cocoa \
--disable-coreaudio
make
}
package() {
cd $pkgname-$pkgver
make -j1 DESTDIR="$pkgdir" install
install -d "$pkgdir"/usr/share/doc/mpv/examples
install -m644 etc/{input,example,encoding-example-profiles}.conf \
"$pkgdir"/usr/share/doc/mpv/examples
install -m644 DOCS/{encoding.rst,tech-overview.txt} \
"$pkgdir"/usr/share/doc/mpv
#install -Dm644 etc/mpv.desktop "$pkgdir"/usr/share/applications/mpv.desktop
}
|
