blob: de2865f60ab0f3604d1a0d346f63c8d05a617dc4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# $Id: PKGBUILD 40102 2011-02-20 03:59:25Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Otto Allmendinger <otto.allmendinger@googlemail.com>
# Contributor: Malte Rabenseifner <malte@zearan.de>
pkgname=murmur
pkgver=1.2.3
pkgrel=1
pkgdesc="The voice chat application server for Mumble"
arch=('i686' 'x86_64')
url="http://mumble.sourceforge.net"
license=('GPL')
depends=('avahi' 'lsb-release' 'protobuf' 'qt>=4.4.0')
makedepends=('boost')
conflicts=('murmur-ice' 'murmur-static' 'murmur-git')
backup=("etc/murmur.ini"
"etc/logrotate.d/murmur"
"etc/conf.d/murmur" )
install="murmur.install"
source=("http://downloads.sourceforge.net/mumble/mumble-$pkgver.tar.gz"
"murmur.rc.d"
"murmur.conf.d"
"murmur.dbus.conf"
"murmur.logrotate.d"
)
md5sums=('55804e3dfe98b16eeb40abca6c254625'
'b99061be67c54bf0bb4a061fd1280281'
'11c1cc875e8021739ec2087252cf0533'
'eddea4cdbd0bde4b960a67e16b5d5478'
'c56726cb267ead68f37f35c28e36e6fa'
)
build() {
cd ${srcdir}/mumble-$pkgver
qmake main.pro CONFIG+="no-client no-ice"
make
}
package() {
cd ${srcdir}/mumble-$pkgver
sed -e "1i# vi:ft=cfg" \
-e "s|database=|database=/var/lib/murmur/murmur.sqlite|" \
-e "s|dbus=session|#dbus=system|" \
-e "s|#logfile=murmur.log|logfile=/var/log/murmur/murmur.log|" \
-e "s|#pidfile=|pidfile=/var/run/murmur/murmur.pid|" \
-e "s|#uname=|uname=murmur|" \
-i scripts/murmur.ini
install -dm755 ${pkgdir}/var/lib/murmur
install -dm755 ${pkgdir}/var/log/murmur
install -dm755 ${pkgdir}/var/run/murmur
install -Dm755 release/murmurd ${pkgdir}/usr/sbin/murmurd
install -Dm644 scripts/murmur.ini ${pkgdir}/etc/murmur.ini
install -Dm755 ${srcdir}/murmur.rc.d ${pkgdir}/etc/rc.d/murmur
install -Dm644 ${srcdir}/murmur.conf.d ${pkgdir}/etc/conf.d/murmur
install -Dm644 ${srcdir}/murmur.dbus.conf \
${pkgdir}/etc/dbus-1/system.d/murmur.conf
install -Dm644 ${srcdir}/murmur.logrotate.d \
${pkgdir}/etc/logrotate.d/murmur
install -Dm644 README ${pkgdir}/usr/share/doc/murmur/README
install -Dm644 man/murmurd.1 ${pkgdir}/usr/share/man/man1/murmurd.1
}
# vim: sw=2:ts=2 et:
|
