blob: a564fc101c39ab0c6f4af61e0f83f06117e92d81 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id: PKGBUILD 111408 2014-05-18 11:46:04Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Otto Allmendinger <otto.allmendinger@googlemail.com>
# Contributor: Malte Rabenseifner <malte@zearan.de>
pkgname=murmur
pkgver=1.2.6
pkgrel=1
pkgdesc="The voice chat application server for Mumble"
arch=('i686' 'x86_64')
url="http://mumble.sourceforge.net"
license=('BSD')
depends=('avahi' 'lsb-release' 'protobuf' 'qt4' 'icu')
makedepends=('boost')
backup=("etc/murmur.ini")
install="murmur.install"
source=("http://downloads.sourceforge.net/mumble/mumble-$pkgver.tar.gz"
"murmur.dbus.conf"
"murmur.service")
md5sums=('32b37ff426863d7abeb1b7c1938652ff'
'eddea4cdbd0bde4b960a67e16b5d5478'
'd27a9adcd7561859e7b033046729bc0e')
build() {
cd ${srcdir}/mumble-$pkgver
qmake-qt4 main.pro CONFIG+="no-client no-ice"
make release
}
package() {
cd ${srcdir}/mumble-$pkgver
sed -e "1i# vi:ft=cfg" \
-e "s|database=|database=/var/lib/murmur/murmur.sqlite|" \
-e "s|#logfile=murmur.log|logfile=|" \
-e "s|#uname=|uname=murmur|" \
-i scripts/murmur.ini
install -dm755 ${pkgdir}/var/lib/murmur
install -Dm755 release/murmurd ${pkgdir}/usr/bin/murmurd
install -Dm644 scripts/murmur.ini ${pkgdir}/etc/murmur.ini
install -Dm644 ${srcdir}/murmur.dbus.conf ${pkgdir}/etc/dbus-1/system.d/murmur.conf
install -Dm644 README ${pkgdir}/usr/share/doc/murmur/README
install -Dm644 man/murmurd.1 ${pkgdir}/usr/share/man/man1/murmurd.1
install -Dm644 ${srcdir}/murmur.service ${pkgdir}/usr/lib/systemd/system/murmur.service
install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
}
# vim: sw=2:ts=2 et:
|
