blob: 108d6605c23d22cb4bda8cb0a9e1d2c4a10dd7b3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# $Id: PKGBUILD 69416 2012-04-16 01:26:19Z jconder $
# Maintainer: Jonathan Conder <jonno.conder@gmail.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>
# Contributor: <kleptophobiac@gmail.com>
# Contributor: dorphell <dorphell@archlinux.org>
pkgname=mythtv
pkgver=0.25
pkgrel=2
epoch=1
pkgdesc="A Homebrew PVR project"
arch=('i686' 'x86_64')
url="http://www.mythtv.org/"
license=('GPL')
depends=('avahi' 'fftw' 'lame' 'libass' 'libavc1394' 'libcdio' 'libiec61883'
'libpulse' 'libva' 'libvdpau' 'libxinerama' 'lirc-utils' 'mesa'
'mysql-clients' 'mysql-python' 'perl-dbd-mysql' 'perl-io-socket-inet6'
'perl-libwww' 'perl-net-upnp' 'python2-lxml' 'qtwebkit' 'urlgrabber'
'x264')
makedepends=('glew' 'libcec' 'libxml2' 'openssl' 'yasm')
optdepends=('glew: for GPU commercial flagging'
'libcec: for consumer electronics control capabilities'
'libxml2: to read blu-ray metadata'
'openssl: for AirTunes (RAOP) support'
'xmltv: to download tv listings')
conflicts=('myththemes')
replaces=('myththemes')
backup=('etc/conf.d/mythbackend')
install='mythtv.install'
source=("ftp://ftp.osuosl.org/pub/$pkgname/$pkgname-$pkgver.tar.bz2"
'mythtv_0.25_gcc_4.7.patch'
'mythbackend.rc'
'mythbackend.conf')
md5sums=('e49c81de40e279c83dcb1b2aa9a45748'
'6090f5f22a8584db80b76cf19869ee41'
'62fd98347c56b1d9b795792f83269d25'
'ab962d83614cbd0ac11ce3fcc929829d')
build() {
cd "$srcdir/$pkgname-$pkgver"
find 'bindings/python' 'contrib' -type f | xargs sed -i 's@^#!.*python$@#!/usr/bin/python2@'
patch -Np1 -i "$srcdir/mythtv_0.25_gcc_4.7.patch"
ARCH="${CARCH/_/-}"
./configure --prefix=/usr \
--cpu="$ARCH" \
--disable-altivec \
--disable-audio-jack \
--disable-ccache \
--disable-distcc \
--enable-libfftw3 \
--enable-libmp3lame \
--enable-libx264 \
--enable-vaapi \
--python=python2
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make INSTALL_ROOT="$pkgdir" install
install -D -m755 "$srcdir/mythbackend.rc" "$pkgdir/etc/rc.d/mythbackend"
install -D -m644 "$srcdir/mythbackend.conf" "$pkgdir/etc/conf.d/mythbackend"
install -D -m644 'database/mc.sql' "$pkgdir/usr/share/mythtv/mc.sql"
mkdir -p "$pkgdir/usr/share/mythtv"
cp -R 'contrib' "$pkgdir/usr/share/mythtv"
mkdir -p "$pkgdir/var/log/mythtv"
}
|
