blob: 5fb175253702b6e3b45671c44e153f3435d98608 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# $Id: PKGBUILD 48169 2011-05-29 12:28:03Z jconder $
# Maintainer: Jonathan Conder <jonno.conder@gmail.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>
# Contributor: <kleptophobiac@gmail.com>
# Contributor: dorphell <dorphell@archlinux.org>
pkgname=mythtv
pkgver=0.24.1
pkgrel=2
epoch=1
pkgdesc="A Homebrew PVR project"
arch=('i686' 'x86_64')
url="http://www.mythtv.org/"
license=('GPL')
depends=('lame' 'libavc1394' 'libiec61883' 'libpulse' 'libvdpau' 'libxinerama'
'libxvmc' 'lirc-utils' 'mesa' 'mysql-clients' 'mysql-python'
'perl-dbd-mysql' 'perl-libwww' 'perl-net-upnp' 'python-lxml' 'qt'
'wget')
makedepends=('yasm')
optdepends=('xmltv: to download tv listings')
backup=('etc/conf.d/mythbackend')
install='mythtv.install'
source=("ftp://ftp.osuosl.org/pub/$pkgname/$pkgname-$pkgver.tar.bz2"
'mythbackend.rc'
'mythbackend.conf'
'mythtv-v4l2-fix.patch')
md5sums=('6870c679619ec58456e76839745411d8'
'feadcc9ad064d93d6dceab1efc0bd9ed'
'bb8e4033d82428d827570fae9ba15e6a'
'ba5c91df80f0d3f7563a873e71a3725c')
build() {
cd "$srcdir/$pkgname-$pkgver"
find 'bindings/python' 'contrib' -type f | xargs sed -i 's@^#!.*python$@#!/usr/bin/python2@'
patch -Np2 -i ${srcdir}/mythtv-v4l2-fix.patch
ARCH="${CARCH/_/-}"
./configure --prefix=/usr --cpu="$ARCH" \
--enable-mmx \
--enable-audio-oss \
--enable-audio-alsa \
--disable-audio-jack \
--enable-audio-pulse \
--disable-altivec \
--disable-distcc \
--disable-ccache \
--enable-vdpau \
--enable-dvb \
--dvb-path=/usr/include \
--enable-lirc \
--enable-joystick-menu \
--enable-v4l \
--enable-ivtv \
--enable-xvmc \
--enable-xvmcw \
--enable-xvmc-vld \
--enable-firewire \
--enable-opengl-vsync \
--enable-xrandr \
--enable-xv \
--enable-x11 \
--with-bindings=perl,python \
--python=python2
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make INSTALL_ROOT="$pkgdir" install
install -D -m755 "$srcdir/mythbackend.rc" "$pkgdir/etc/rc.d/mythbackend"
install -D -m644 "$srcdir/mythbackend.conf" "$pkgdir/etc/conf.d/mythbackend"
install -D -m644 'database/mc.sql' "$pkgdir/usr/share/mythtv/mc.sql"
mkdir -p "$pkgdir/usr/share/mythtv"
cp -R 'contrib' "$pkgdir/usr/share/mythtv"
}
|
