blob: ddb05ed1185b897a24eaeec7860687f3703139a6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# $Id: PKGBUILD 112285 2014-05-30 22:35:48Z faidoc $
# Maintainer: Alexandre Filgueira <alexfilgueira@cinnarch.com>
# Contributor: Ner0
pkgname=nemo
pkgver=2.2.2
pkgrel=1
pkgdesc="Cinnamon file manager (Nautilus fork)"
arch=('i686' 'x86_64')
url="https://github.com/linuxmint/nemo"
license=('GPL')
depends=('libexif' 'gvfs' 'dconf' 'desktop-file-utils' 'exempi' 'python2'
'cinnamon-desktop' 'gnome-icon-theme' 'libnotify' 'libxml2'
'cinnamon-translations')
makedepends=('gtk-doc' 'gobject-introspection' 'intltool' 'gnome-common' 'python2-gobject' 'python2-polib')
options=('!emptydirs')
install=nemo.install
source=("$pkgname-$pkgver.tar.gz::https://github.com/linuxmint/nemo/tarball/$pkgver"
"adwaita_style.patch")
sha256sums=('452b3720eceb7ae591ce9e1875cb555f531822d8ba73184ea241561d8ad624b2'
'21555779bc9d2cc87f73042039bcffd43a3d858a7f1f3a93ec27c91cdf69d4ce')
prepare() {
cd linuxmint-nemo-*
# Python2 fix
sed -i 's/bin\/python/bin\/python2/g' files/usr/share/nemo/actions/myaction.py
find -type f | xargs sed -i 's@^#!.*python$@#!/usr/bin/python2@'
# Fix white text on breadcrumb with Adwaita theme
patch -Np1 -i ../adwaita_style.patch
# Fix desktop style with Adwaita theme
sed -i 's/add_class (\(.*\), "nemo-/add_class (\1, "nautilus-/' \
libnemo-private/nemo-icon-{canvas-item,container}.c
# Fix build
sed -i '/AC_SUBST(DISABLE_DEPRECATED_CFLAGS)/d' configure.in
# Rename 'Files' app name to avoid having the same as nautilus
sed -i 's/^Name\(.*\)=.*/Name\1=Nemo/' data/nemo.desktop.in.in
}
build() {
cd linuxmint-nemo-*
./autogen.sh --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static \
--libexecdir=/usr/lib/nemo \
--disable-update-mimedb \
--disable-tracker \
--disable-gtk-doc-html \
--disable-schemas-compile
make
}
package() {
cd linuxmint-nemo-*
make DESTDIR="$pkgdir/" install
}
|
