blob: 948bf38d679a2e2e8cab2b77268a77031a6a25ca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id: PKGBUILD 95677 2013-08-15 12:59:27Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Paulo Matias <matiasΘarchlinux-br·org>
# Contributor: Georgij Kondratjev <smpuj@bk.ru>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=netsurf
pkgver=3.0
pkgrel=3
pkgdesc='Lightweight and fast web browser'
arch=('x86_64' 'i686')
url='http://www.netsurf-browser.org/'
license=('MIT' 'GPL2')
depends=('gtk2' 'libmng' 'curl' 'librsvg' 'desktop-file-utils' 'libnsbmp' 'libnsgif' 'libcss' 'libwebp' 'libdom') # 'libharu' 'gstreamer0.10'
makedepends=('js' 're2c' 'lcms' 'gendesk' 'netsurf-buildsystem' 'libglade')
install="$pkgname.install"
source=("netsurf.png::http://ubuntu.allmyapps.com/data/n/e/netsurf-netsurf-web-browser/icon_48x48_netsurf.png"
"http://download.$pkgname-browser.org/$pkgname/releases/source/$pkgname-$pkgver-src.tar.gz")
sha256sums=('f0dbcc5d80bf03d706aa8b28a322aa7f169a40813848c2d1505691f6e2c7ef00'
'7c6a48d3cc3e9a3e3a51b532ddf60f7697e97bf8b61a6d3b2ced1a2e89fbccc6')
prepare() {
cd "$pkgname-$pkgver"
gendesk --pkgname "$pkgname" --pkgdesc "$pkgdesc" --exec 'netsurf %U' \
--genericname 'Web Browser' --comment 'Lightweight web browser' \
--mimetypes 'text/html;application/xhtml+xml;x-scheme-handler/http;x-scheme-handler/https;x-scheme-handler/geo'
}
build() {
cd "$pkgname-$pkgver"
make \
PREFIX=/usr \
TARGET=gtk \
NETSURF_USE_WEBP=YES \
NETSURF_USE_VIDEO=NO \
NETSURF_USE_MOZILLA_JS=YES \
NETSURF_USE_HARU_PDF=NO
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make install PREFIX=/usr DESTDIR="$pkgdir"
install -Dm644 "../$pkgname.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
install -Dm644 "$pkgname.desktop" \
"$pkgdir/usr/share/applications/$pkgname.desktop"
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=2 sw=2 et:
|
